【已解决】批处理查找文件夹路径并替换注册表文件内路径？

大地

查找文件夹路径并替换注册表文件内路径

以下码在XP系统中能运行，本以为正确了，改成已解决，后发现在在win10中出错，无法运行，汗颜！！所以重新提交求助，望大神邦忙，感 谢。


批处理通过所有分区深层子目录中搜索，查到第一个文件夹PETOOLS后中止搜索，并把注册表1.reg中原有的路径C:\\PETOOLS替换为新的路径，注意：注册表路径是双斜杠\\,，单斜杠是无法导入注册表的，路径中没有空格也没特殊字符，也不需要搜索分区根目录，只要子目录，不要用wmic 也不要用poseerhsell 批处理代码如何写？

以下是代码在XP中能运行，在win10中出错：

@echo off
setlocal enabledelayedexpansion

set "target=PETOOLS"
set "regfile=1.reg"
set "found="

rem 遍历所有分区（C到Z）
for %%d in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
    if exist %%d:\ (
        echo 正在搜索 %%d 盘...
        rem 搜索子目录（排除根目录）
        for /f "delims=" %%a in ('dir /s /b /ad %%d:\%target% 2^>nul') do (
            set "path=%%a"
            rem 验证是否为子目录（路径包含两级以上目录）
            if not "%%~dpa"=="%%d:\" (
                rem 转义路径中的单斜杠为双斜杠
                set "newpath=!path:\=\\!"
                set "found=!newpath!"
                goto replace
            )
        )
    )
)

:replace
if defined found (
    echo 替换目标路径为: %found%
    rem 创建临时文件并写入替换后的内容
    (
        for /f "usebackq delims=" %%i in ("%regfile%") do (
            set "line=%%i"
            set "line=!line:C:\\PETOOLS=%found%!"
            echo !line!
        )
    ) > "%regfile%.tmp.reg"

    rem 替换原文件
    move /y "%regfile%.tmp.reg" "%regfile%" > nul
    echo SUCCESS
) else (
    echo FAILED
)

endlocal
pause

Five66

move /y "%regfile%.tmp""%regfile%">nul
参数那里连在一起了??? 分开来???

大地

回复 2# Five66
分开后   测试也不行     应该不是这个问题

Five66

回复 3# 大地


    把运行后的结果发出来看看

大地

回复 4# Five66 但
显示运行成功，但1.reg内容如下了：


F:\rr>(
set "line=C:\\PETOOLS"  
set "line=!line:C:\\PETOOLS=F:\\rr\\kkkk\\PETOOLS!"  
echo !line!
)
F:\\rr\\kkkk\\PETOOLS

多了上面5行
原来的C:\\PETOOLS  变为  F:\\rr\\kkkk\\PETOOLS  是对的  就是多了上面5行

Five66

回复 5# 大地


    1.reg编码是啥???

大地

回复 6# Five66

ANSI

Five66

回复 7# 大地


    啊? ,开头不加上@echo off的??

窄口牛

pecmd脚本直接搞不出来？

大地

追加求助，....

77七

应该是查找文件夹的姿势不对，不是系统差异，是文件夹位置差异

1. @echo off
   
2. cd /d "%~dp0"
   
3. set "target=PETOOLS"
   
4. set "regfile=1.reg"
   
5. set "found="
   
6. for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
   
7.         if exist "%%a:\" (
   
8.                 for /f "delims=" %%d in ('dir /b /s /ad "%%a:\%target%?"') do (
   
9.                         if /i "%%~nxd" equ "%target%" (
   
10.                                 if /i "%%d" neq "%%a:\%target%" (
    
11.                                         set found=%%d
    
12.                                         call set "found=%%found:\=\\%%"
    
13.                                         goto :replace
    
14.                                 )
    
15.                         )
    
16.                 )
    
17.         )
    
18. )
    
19. :replace
    
20. if defined found (
    
21.         (for /f "delims=" %%a in ('find /n /v "" ^< "%regfile%"') do (
    
22.                 set str=%%a
    
23.                 setlocal enabledelayedexpansion
    
24.                 set "str=!str:C:\\PETOOLS=%found%!"
    
25.                 echo=!str:*]=!
    
26.                 endlocal
    
27.         )) > #
    
28.         move # "%regfile%"
    
29.         echo SUCCESS
    
30. ) else (
    
31.         echo FAILED
    
32. )
    
33. pause
    

复制代码

aloha20200628

回复 1# 大地

忽略 C 盘，从 D 盘开始遍历盘符...

1. 
   
2. @echo off &echo,正在处理...&setlocal enabledelayedexpansion &for %%D in (
   
3.         D E F G H I J K L M N O P Q R S T U V W X Y Z
   
4. ) do if exist "%%D:\" for /f "delims=" %%d in ('dir /b/s/ad %%D:\PETOOLS 2^>nul') do (
   
5.   set "d=%%d" &set "d=!d:\=\\!"
   
6.   (for /f "delims=" %%a in (1.reg) do (
   
7.       set "a=%%a" &if /i "!a!"=="!a:c:\\PETOOLS=!" (echo,%%a) else (
   
8.       set "ok=1" &for %%x in ("!d!") do echo,!a:c:\\PETOOLS=%%~x!)
   
9.   ))>#.#
   
10.   (if !ok! equ 1 move /y #.# 1.reg) &goto:[end]
    
11. )
    
12. :[end]
    
13. pause&exit/b
    

复制代码

大地

回复 11# 77七


    测试成功，谢谢大佬！

大地

回复 12# aloha20200628


    测试成功，谢谢大佬！！！