[已解决]将一张指定路径的png透明logo图片，按原尺寸放到本文件夹中每一张图的左下角

crownking1983

跪求批处理将一张指定路径的png格式的透明logo图片,按原尺寸放到本文件夹中每一张图的左下角，文件夹里的图片是jpg png jpeg三种格式的图片

老板给安排了一个任务，做了一个1200*1200的长条LOGO，要批量将这个LOGO用水印的形式，镶嵌到每一张产品海报里。

这批产品海报有1600多张，虽然尺寸都是同宽度的，但是图长短不一，有的贼长贼长的，老板又要求统一放到左下角，无法用PS动作录制功能实现

如果一个一个PS，这1600张长短比例都不统一的图我一个一个弄我手得废！跪求大神拯救我了！

注：这个LOGO不仅是透明背景，LOGO文字本身也是10%透明度的半透明，是批量给图加水印的思路

jiavip

研究一下 Photoshop 脚本吧!
在Photoshop中，通过 文件 > 脚本 > 浏览 即可选择并运行你下载的 .jsx 脚本文件,
语法基本和JS & VBS 没啥区别,判断 & 函数 & 变量 & 表达 有很多都一样,,,
只不过有些特殊动作的函数不一样而已..!
现在借助 A1 写 Photoshop 脚本很简单的,
只不过写出来的脚本只适合自己定制的工作场景,,,

Batcher

批处理给图片添加文字水印的几种方法
https://mp.weixin.qq.com/s/NhjgwVzrzCegpIYo5iYEyA

批处理获取照片EXIF添加日期水印
https://mp.weixin.qq.com/s/Ak-FXiCJt5FXgVNBpgKpvg

批处理给照片添加随机图片水印
https://mp.weixin.qq.com/s/mSfzh4YhBYGjiRpuOn6L7A

Batcher

批处理给照片添加固定位置、固定图片的水印

1. @echo off
   
2. setlocal enabledelayedexpansion
   
3. REM 1、下载并安装 ImageMagick 这个命令行工具
   
4. REM https://imagemagick.org/download/#windows
   
5. REM 2、根据自己电脑实际安装路径设置以下临时环境变量
   
6. set "path=C:\Program Files\ImageMagick;%path%"
   
7. 
   
8. REM 设置待处理的照片所在的目录
   
9. set "FolderOld=D:\Test\照片"
   
10. REM 设置水印图片所在的完整路径
    
11. set "FileWM=D:\Test\水印\LOGO.png"
    
12. REM 设置添加水印之后的照片所在的目录
    
13. set "FolderNew=D:\Test\合成"
    
14. 
    
15. REM 假设待处理的照片有jpg、png、jpeg三种格式，如有需要可以继续添加
    
16. set "ListExt=jpg png jpeg"
    
17. set "PictureType="
    
18. for %%i in (%ListExt%) do (
    
19.     set "PictureType=!PictureType! *.%%i"
    
20. )
    
21. 
    
22. REM 水印位置参数列表
    
23. REM 左上 NorthWest
    
24. REM 中上 North
    
25. REM 右上 NorthEast
    
26. REM 左中 West
    
27. REM 正中 Center
    
28. REM 右中 East
    
29. REM 左下 SouthWest
    
30. REM 中下 South
    
31. REM 右下 SouthEast
    
32. 
    
33. cd /d "%FolderOld%"
    
34. for /f "delims=" %%i in ('dir /b /a-d !PictureType!') do (
    
35.     echo %%i
    
36.     magick.exe composite -gravity SouthWest "%FileWM%" "%%i" "%FolderNew%\%%i"
    
37. )
    
38. for /f "delims=" %%a in ('dir /b /ad') do (
    
39.     echo --- %%a
    
40.     if not exist "%FolderNew%\%%a" (
    
41.         md "%FolderNew%\%%a"
    
42.     )
    
43.     pushd "%%a"
    
44.     for /f "delims=" %%i in ('dir /b /a-d !PictureType!') do (
    
45.         echo %%i
    
46.         magick.exe composite -gravity SouthWest "%FileWM%" "%%i" "%FolderNew%\%%a\%%i"
    
47.     )
    
48.     popd
    
49. )
    
50. endlocal

复制代码

aloha20200628

给一个简化脚本如下（存放在底图根目录下运行），输出的每个合成图片保持底图格式；代码第一行假设 logo 图片的路径，楼主可自定义，将其与要处理的底图文件夹分开即可。

test.bat

1. @echo off &setlocal &set "logoF=d:\logo\logo.png"
   
2. for /f "delims=" %%F in ('dir /b/s/a-d *.jpg *.jpeg *.png') do magick "%%F" "%logoF%" -gravity southwest -composite "%%~dpnF.new%%~xF"
   
3. pause&exit/b

复制代码

77七

设定 logo 宽度 = 图片宽度的 12%

AI（有修改）：

1. @echo off
   
2. setlocal EnableDelayedExpansion
   
3. cd /d "%~dp0"
   
4. 
   
5. set "Logo=logo.png"
   
6. set "OutDir=输出"
   
7. set "Percent=12"
   
8. set "MarginX=20"
   
9. set "MarginY=20"
   
10. 
    
11. where magick >nul 2>nul || (
    
12.     echo [错误] 未找到 ImageMagick
    
13.     pause
    
14.     exit /b
    
15. )
    
16. 
    
17. if not exist "%Logo%" (
    
18.     echo [错误] 找不到 %Logo%
    
19.     pause
    
20.     exit /b
    
21. )
    
22. 
    
23. if not exist "%OutDir%" md "%OutDir%"
    
24. 
    
25. for %%F in (*.jpg *.jpeg *.png) do (
    
26.     if /i not "%%~nxF"=="%Logo%" (
    
27. 
    
28.         for /f %%W in ('magick identify -format "%%w" "%%F"') do (
    
29.             set /a LogoW=%%W*%Percent%/100
    
30.         )
    
31. 
    
32.         echo [处理中] %%~nxF  logo宽=!LogoW!px
    
33. 
    
34.         magick "%%F" ^
    
35.             ^( "%Logo%" -resize !LogoW!x ^) ^
    
36.             -gravity southwest ^
    
37.             -geometry +%MarginX%+%MarginY% ^
    
38.             -composite ^
    
39.             "%OutDir%\%%~nxF"
    
40.             chcp 936 >nul
    
41.     )
    
42. )
    
43. 
    
44. echo.
    
45. echo 全部完成
    
46. pause

复制代码

crownking1983

各位大神！！感谢！！你们的都能用啊！！太牛逼了！！！！！！

crownking1983

aloha20200628 发表于 2026-8-21 11:03
给一个简化脚本如下（存放在底图根目录下运行），输出的每个合成图片保持底图格式；代码第一行假设 logo 图 ...

大神！老板今天突然改变主意了，他说不放左下角了，让我把水印放到文件夹里每一张图的随机任意位置
也就是说，水印不再放到每一张图的固定位置了，而是随机一个任意位置
那么这个代码应该怎么改呢？急，好人一生平安

crownking1983

77七 发表于 2026-8-21 11:23
设定 logo 宽度 = 图片宽度的 12%

AI（有修改）：

大神！老板今天突然改变主意了，他说不放左下角了，让我把水印放到文件夹里每一张图的随机任意位置
也就是说，水印不再放到每一张图的固定位置了，而是随机一个任意位置
那么这个代码应该怎么改呢？急，好人一生平安

crownking1983

Batcher 发表于 2026-8-21 09:16
批处理给照片添加固定位置、固定图片的水印

大神！老板今天突然改变主意了，他说不放左下角了，让我把水印放到文件夹里每一张图的随机任意位置
也就是说，水印不再放到每一张图的固定位置了，而是随机一个任意位置
那么这个代码应该怎么改呢？急，好人一生平安

crownking1983

感谢各路神仙，跪求帮忙。
老板今天突然改变主意了，他说不放左下角了，让我把水印放到文件夹里每一张图的随机任意位置
也就是说，水印不再放到每一张图的固定位置了，而是随机一个任意位置
那么这个代码应该怎么改呢？急，好人一生平安

77七

crownking1983 发表于 2026-8-24 11:19
感谢各路神仙，跪求帮忙。
老板今天突然改变主意了，他说不放左下角了，让我把水印放到文件夹里每一张图的 ...

回复一次就行了，大家都能看到。

AI：（有修改，已测试）

1. @echo off
   
2. chcp 936 >nul
   
3. setlocal EnableDelayedExpansion
   
4. cd /d "%~dp0"
   
5. 
   
6. set "Logo=logo.png"
   
7. set "OutDir=output"
   
8. set "Percent=12"
   
9. 
   
10. where magick >nul 2>nul || (
    
11.     echo [ERROR] ImageMagick was not found.
    
12.     pause
    
13.     exit /b
    
14. )
    
15. 
    
16. if not exist "%Logo%" (
    
17.     echo [ERROR] Logo file not found: %Logo%
    
18.     pause
    
19.     exit /b
    
20. )
    
21. 
    
22. if not exist "%OutDir%" md "%OutDir%"
    
23. 
    
24. rem Get original logo dimensions
    
25. for /f "tokens=1,2" %%A in ('magick identify -format "%%w %%h" "%Logo%"') do (
    
26.     set "LogoSrcW=%%A"
    
27.     set "LogoSrcH=%%B"
    
28. )
    
29. chcp 936 >nul
    
30. 
    
31. for %%F in (*.jpg *.jpeg *.png) do (
    
32.         if /i not "%%~nxF"=="%Logo%" (
    
33. 
    
34.                 rem Get image dimensions
    
35.                 for /f "tokens=1,2" %%A in ('magick identify -format "%%w %%h" "%%F"') do (
    
36.                         set "ImgW=%%A"
    
37.                         set "ImgH=%%B"
    
38.                 )
    
39.                 chcp 936 >nul
    
40. 
    
41.                 rem Logo width = image width * Percent
    
42.                 set /a LogoW=ImgW*Percent/100
    
43.                 set /a LogoH=LogoW*LogoSrcH/LogoSrcW
    
44. 
    
45.                 rem Prevent logo from exceeding image height
    
46.                 if !LogoH! GTR !ImgH! (
    
47.                         set /a LogoH=ImgH
    
48.                         set /a LogoW=ImgH*LogoSrcW/LogoSrcH
    
49.                 )
    
50. 
    
51.                 set /a MaxX=ImgW-LogoW
    
52.                 set /a MaxY=ImgH-LogoH
    
53.                 rem Generate larger random numbers than %%RANDOM%% alone
    
54.                 set /a "R1=!random!*32768+!random!"
    
55.                 set /a "R2=!random!*32768+!random!"
    
56.                 set /a "X=R1 %% (MaxX+1)"
    
57.                 set /a "Y=R2 %% (MaxY+1)"
    
58. 
    
59.                 echo [Processing] %%~nxF  Logo: !LogoW!x!LogoH!  Position: !X!,!Y!
    
60. 
    
61.                 magick "%%F" ^
    
62.                         ^( "%Logo%" -resize !LogoW!x!LogoH! ^) ^
    
63.                         -gravity northwest ^
    
64.                         -geometry +!X!+!Y! ^
    
65.                         -composite ^
    
66.                         "%OutDir%\%%~nxF"
    
67. 
    
68.                 chcp 936 >nul
    
69.         )
    
70. )
    
71. 
    
72. echo.
    
73. echo 完成
    
74. pause

复制代码

Batcher

crownking1983 发表于 2026-8-24 11:18
大神！老板今天突然改变主意了，他说不放左下角了，让我把水印放到文件夹里每一张图的随机任意位置
也就 ...

请看3楼第三个链接，里面有完整代码。

aloha20200628

crownking1983 发表于 2026-8-24 11:17
大神！老板今天突然改变主意了，他说不放左下角了，让我把水印放到文件夹里每一张图的随机任意位置
也就 ...

test.bat

1. @echo off &setlocal &set "logoF=d:\logo\logo.png"
   
2. for /f "tokens=1,2 delims= " %%a in ('magick identify -format "%%w %%h" "%logoF%" ') do set/a "_w=%%a,_h=%%b"
   
3. for /f "delims=" %%F in ('dir /b/s/a-d *.jpg *.jpeg *.png') do (
   
4.    for /f "tokens=1,2 delims= " %%a in ('magick identify -format "%%w %%h" "%%F" ') do set/a "xm=%%a-%_w%, ym=%%b-%_h%"
   
5.    setlocal enabledelayedexpansion
   
6.    set/a "xr=!random!%%(!xm!+1), yr=!random!%%(!ym!+1)"
   
7.    magick "%%F" "%logoF%" -geometry +!xr!+!yr! -composite "%%~dpnF.new%%~xF" &endlocal )
   
8. exit/b

复制代码

crownking1983

77七 发表于 2026-8-24 11:54
回复一次就行了，大家都能看到。

AI：（有修改，已测试）

再次谢谢啊@ 上次三位大神都帮忙，十分感激，所以分别回复了一下