@echo off

::-----S----------QQ自动登录数据------------------------------------
::QQData 显示1_362220083_加密后的密码
::QQData 显示2_QQ号_依旧是加密
::QQData 显示3_QQ号_加密密码
::-----E------------------------------------------------------------

::-----S----------功能开关(开启={Nul}，关闭=::，调试=echo )--------
set Exp_NotDebug=
set Exp_NoSelect=
set Exp_AutoLogo=
set Exp_SearchPath=::
::-----E------------------------------------------------------------

::-----S----------Exp_AutoLogo--------------------------------------
set AutoLogoNum=
::-----E------------------------------------------------------------

::-----S----------Exp_SearchPath------------------------------------
set QQPath=D:\Program Files\Tencent\QQ
::-----E------------------------------------------------------------
@echo on

%Exp_NotDebug%@echo off
title QQ自动登陆工具--小蔡专用
%Exp_NotDebug%mode.com con: cols=35 lines=3
color a
setlocal ENABLEDELAYEDEXPANSION
setlocal ENABLEEXTENSIONS
echo.
echo. 初始化...
set AppPath=%QQPath%
%Exp_SearchPath%for /f "tokens=1,2*" %%a in ('reg.exe query HKLM\SOFTWARE\Tencent\QQ /v install ^|find /i "install"') do set AppPath=%%c
if [!AppPath!]==[] (set Timer=10 &goto FindErr)
if "!AppPath:~-1!"=="\" (set AppPath=!AppPath:~0,-1!)
if not exist "!AppPath!\QQ.exe" (set Timer=10 &goto FindErr)
set LineSum=3
for /f %%i in ('type %~s0^|find.exe /i "::QQData"') do (
if /i "%%i"=="::QQData" (set /a LineSum=!LineSum!+1)
)
%Exp_NotDebug%mode.com con: cols=35 lines=!LineSum!

REM 如果检测只有一条记录(原本的3行+1行数据)，直接赋值并启动，跳过显示列表部分
if /i !LineSum! EQU 4 (set Chose=1 &set QQSum=1 &goto MainQQ)

REM 自动登录，根据登陆条件，直接赋值并启动
%Exp_AutoLogo%if not "%AutoLogoNum%"=="" (set Chose=%AutoLogoNum% &set QQSum=99 &goto MainQQ)

%Exp_NotDebug%cls
color d
echo.
for /f "tokens=1,*" %%a in ('type %~s0^|find.exe /i "::QQData"') do (
if /i "%%a"=="::QQData" (
for /f "tokens=1,2,* delims=_" %%i in ("%%b") do (
set /a QQSum=!QQSum!+1
echo+ !QQSum!. %%i[%%j]
)
)
)
echo.
set /p Chose=选择[1-!QQSum!]:

:MainQQ
color d
%Exp_NotDebug%cls
::-----S------若没有选择，直接回车，则默认第一项------------
%Exp_NoSelect%if "%Chose%"=="" (set Chose=1 &set QQSum=1 &goto MainQQ)
::-----E----------------------------------------------------
if /i %Chose% LSS 1 (exit)
if /i %Chose% GTR !QQSum! (exit)
set /a CenterNum=!LineSum!/2
set /a SortLineNum=!LineSum!-1
set QQSum=0
for /f "tokens=1,*" %%a in ('type %~s0^|find.exe /i "::QQData"') do (
if /i "%%a"=="::QQData" (
set /a chkNum=!chkNum!+1
if /i %Chose% EQU !chkNum! ( 
for /f "tokens=1,2,* delims=_" %%i in ("%%b") do (
for /l %%x in (1,1,!SortLineNum!) do (
if /i %%x NEQ !CenterNum! (echo+) else (echo+ %%i_%%j)
)
start "" /d"!AppPath!" "!AppPath!\QQ.exe" /START QQUIN:%%j PWDHASH:%%k /STAT:40
)
)
)
)
ping.exe 127.1 -n 4 >nul 2>nul
::taskkill.exe /im TIMPlatform.exe /f >nul 2>nul
::taskkill.exe /im TXPlatform.exe /f >nul 2>nul
exit

:FindErr
if [!Timer!]==[0] exit
set /a Timer=!Timer!-1
mode con: cols=36 lines=9
color a
cls
echo [!Timer!] 秒后自动退出
echo.
echo The QQ-Tool not find QQ.exe
echo Please correctly install Client
echo.
echo 本工具未发现QQ.exe
echo 请正确安装QQ客户端
echo.
ping 127.0.0.1 -n 2 >nul 2>nul
goto FindErr
复制代码

for /f "tokens=1,2,3,4,5,6" %%a in ('ping www.baidu.com -n 1^|find "time="') do if not "%%e" == "" set b%%e
复制代码

: downlb
::校验
::版本
set soydb=1.20
::服务器地址
set soydw=http://down.lpfcn.cn/cmddown/
::被更新文件名
set soydm=默认网关.cmd
call :downvb %soydw%downLB.txt %tmp%\downLB.txt
if exist %tmp%\downLB.txt for /f "eol=# tokens=1" %%a in (%tmp%\downLB.txt) do set soyd%%a &&if "%%a" == "mz=%soydm%" goto :downgx
goto :EOF
:downvb
::下载 添加^符号防误杀
echo on error resume next:Set P=Crea^teObject("Microsoft.XMLHTTP"):.O^pen "GET","%1",0.Send()::Set G=Cre^ateObject("ADODB.Stream")>%tmp%\tmp.vbs
echo G.Mode=3:G.Type=1:G.Open()::G.Wr^ite(P.response^Body):G.SaveToFile "%2",2 >>%tmp%\tmp.vbs
call %tmp%\tmp.vbs
goto :EOF
:downgx
::更新
if %soydb2% gtr %soydb% (
call :downvb %soydw%%soydwj% %soydwj%
if exist %soydm% del %soydm%
ren %soydwj% %soydm%
if exist %soydm% echo :%soydgxcg%
%soydm%
)
echo :%soydgxsb%
%0
复制代码

 
@echo off
setlocal enabledelayedexpansion
set p0=48&set p1=49&set p2=50&set p3=51&set p4=52&set p5=53
set p6=54&set p7=55&set p8=56&set p9=57&set pA=65&set pB=66
set pC=67&set pD=68&set pE=69&set pF=70
:back
set /p 源数=请输入序列号=
for /f "skip=1 delims=:" %%i in ('^(echo "%源数%"^&echo.^)^|findstr /o ".*"') do set/a l=%%i-5
if not "%l%"=="8" (echo 字符必须满足8位&goto back)
set scanf=%源数%
set sed=85930483
set regcode=0
:loop
call set str1=%scanf:~,1%
call set numtemp=%%p%str1%%%
set /a regcode=%regcode%+%sed%-(1024%%(%numtemp%))
set "scanf=%scanf:~1%"
if defined scanf goto loop
set 源数=%regcode%
set /a 源数=%源数% || goto :eof
:dosomething
set /a 余数 = %源数% %% 16
set /a 源数 /= 16
call :转换 %余数% 
set 余数=%ret%
set 计算结果=%余数%%计算结果%
if %源数% lss 16 goto end
goto dosomething
:转换
set ret=
if "%1" == "10" set ret=A
if "%1" == "11" set ret=B
if "%1" == "12" set ret=C
if "%1" == "13" set ret=D
if "%1" == "14" set ret=E
if "%1" == "15" set ret=F
if %1 lss 10 set ret=%1
goto :eof
:end
call :转换 %源数%
set 源数=%ret%
if "%源数%" == "0" set 源数=
echo 您的注册码为=%源数%%计算结果% 
echo.
echo 感谢您使用 BatProject
echo.
echo -----------------------------------
echo 感谢BatHome上一些同学提供的帮助。。。
echo.
echo.欢迎访问 http://Neoix.008.net/
set ret=
set 源数=
set 余数=
set 计算结果=
pause>nul
start http://neoix00.freebsdhost.org/Get/reg.php
exit
复制代码