批处理之家 - Powered by Discuz! Board

标题: [其他] [分享]批处理把命令结果的某一部分显示为不同的颜色 [打印本页]

作者: Batcher 时间: 2021-9-5 20:36 标题: [分享]批处理把命令结果的某一部分显示为不同的颜色

【问题】

C:\>net user administrator | findstr /c:"帐户启用"
帐户启用 No

C:\>想让后面的No显示不一样的颜色

【代码】

test1.bat

@echo off
set esc=[
for /f "tokens=1-2" %%i in ('net user administrator ^| findstr /c:"帐户启用"') do (
    set /p =%%i <nul
    echo %esc%38;2;0;255;0m%%j
    echo %esc%0m
)
pause
复制代码

test2.bat

@echo off
for /f %%i in ('echo prompt $E ^| cmd') do (
    set "KeyESC=%%i"
)
for /f "tokens=1-2" %%i in ('net user administrator ^| findstr /c:"帐户启用"') do (
    set /p =%%i <nul
    echo %KeyESC%[38;2;0;255;0m%%j%KeyESC%[0m
)
pause
复制代码

test3.bat

@echo off
for /f %%i in ('"prompt $E & for %%j in (1) do rem"') do (
    set "KeyESC=%%i"
)
for /f "tokens=1-2" %%i in ('net user administrator ^| findstr /c:"帐户启用"') do (
    set /p =%%i <nul
    echo %KeyESC%[38;2;0;255;0m%%j%KeyESC%[0m
)
pause
复制代码

作者: hlzj88 时间: 2021-9-5 20:47

win7 黑白的，。火绒立杀。

作者: Batcher 时间: 2021-9-5 20:50

回复 2# hlzj88

尽早淘汰Win7

作者: ximen 时间: 2021-9-5 21:26

感谢大佬专门开贴解答。看了半天findstr也没学会。唉，说到底还是基本功太差！得好好学习才是。

作者: Batcher 时间: 2021-9-5 21:53

回复 4# ximen

试试这个能否看懂：批处理显示彩色字符的原理及其中退格符的作用
http://bbs.bathome.net/thread-1331-1-1.html#pid11864

作者: 路过 时间: 2021-9-5 23:23

VT100么，效率是真高

欢迎光临批处理之家 (http://bbs.bathome.net/)