[原创] 批处理位运算

pusofalse

发现很多新手对于批处理中set/a的位运算的概念有点模糊，我也是，什么“异、或、与、逻辑移位”，看的云里雾里，头脑发胀，于是就有了下面的代码。

@echo off
if "%~1" equ "" exit/b
:begin
setlocal enabledelayedexpansion
set "Var=0123456789ABCDEF"
set/p number=Input: 
if /i "%number%" equ "cls" cls&endlocal&goto begin
if "%~1" equ ">>" (set "s=!number: ="^>^>"!") else (
    if "%~1" equ "<<" (set "s=!number: ="^<^<"!") else (
       set "s=!number: ="^%~1^"!"
))
set/a s=!s!
for %%a in (%number% %s%) do (
     set/a num=%%a,y+=1
     set "bin="
     call :loop
     if !y! equ 2 (set "str=                  (%~1) %%a") else (set "str=                         %%a")
     set "bin=00000000000000000000000000000!bin!"
     if !y! equ 3 echo      ------------------------------------------------------
     echo  !str:~-15!  ^(bin^) !bin:~-30!
)
endlocal
echo.&goto begin
:loop
set/a Mod=Num%%2,Num/=2
call,set "bin=%%Var:~%Mod%,1%%%bin%"
if %Num% neq 0 goto loop
复制代码

使用见图：

此批处理没有对输入信息进行排错处理，所以不要输入08、09、0x9k abc这类无效的文字。
第一次运行时，务必输入参数，比如你想知道>>右移运算，就打开CMD，输入：批处理名字 ">>"，此后输入的信息，都会执行>>右移运算，若要进行其他运算，CTRL+C终止，重新运行此批处理。
如果要进行^位相异运算，就输入 批处理名字 "^"，同上。
运算符因为都是特殊字符，所以要加""闭合。
例：比如想知道19"&"2的运算信息，就打开CMD，输入 批处理名字 "&"
等待提示input，输入: 19 2 回车，便会出现19"&"2的运算结果。
&---与，转为2进制，对应位上相乘。
其他同样的道理，希望能从结果中总结出各位运算符的含义。