[日期时间] [已解决]批处理怎样输出当前日期时间减去指定分钟数后的日期时间？

随风

输出当前日期时间减去指定分钟数后的日期时间
要求：输入一个日期、时间，如：2011-07-13-00:03
输出: 2011-07-12-23:58
即:输入的时间减去5分钟
需考虑跨天,跨月,跨年,以及平润年.

代码要求:不产生临时文件,尽量简洁

zdzjs

感谢Batcher ，正找这方面的资料。

随风

re 9楼 ArdentMan
谢谢，可以了 ^_^

re 10楼 batcher
谢谢..

Batcher

@echo off
set TimeNow=2011-07-13 00:03
set MinsInter=5
call :DateToMins %TimeNow:~0,4% %TimeNow:~5,2% %TimeNow:~8,2% %TimeNow:~11,2% %TimeNow:~14,2% MinsNow
set /a MinsResult=MinsNow-MinsInter
call :MinsToDate %MinsResult% yy mm dd hh nn
set TimeResult=%yy%-%mm%-%dd% %hh%:%nn%
echo,%TimeResult%
pause
goto :eof
 
:DateToMins %yy% %mm% %dd% %hh% %mm% result
setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3&set hh=%4&set nn=%5
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
if 1%hh% LSS 20 set hh=0%hh%
if {%nn:~2,1%} EQU {p} if "%hh%" NEQ "12" set hh=1%hh%&set/a hh-=88
if {%nn:~2,1%} EQU {a} if "%hh%" EQU "12" set hh=00
if {%nn:~2,1%} GEQ {a} set nn=%nn:~0,2%
set /a hh=100%hh%%%100,nn=100%nn%%%100,j=j*1440+hh*60+nn
endlocal&set %6=%j%&goto :EOF
 
:MinsToDate %mins% yy mm dd hh nn
setlocal ENABLEEXTENSIONS
set /a i=%1,nn=i%%60,i/=60,hh=i%%24,dd=i/24,i/=24
set /a a=i+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
(if %hh% LSS 10 set hh=0%hh%)&(if %nn% LSS 10 set nn=0%nn%)
endlocal&set %6=%nn%&set %5=%hh%&set %4=%dd%&^
set %3=%mm%&set %2=%yy%&goto :EOFCOPY

ArdentMan

7# 随风
系统日期格式决定了VBS的输出格式，这个只要改下Next标签中的For语句就可以了啊

随风

6# Batcher

是的，那几个函数看得我头大 ^_^

随风

5# ArdentMan [/b

谢谢，你的代码可行，但我的系统日期格式是:  07-13 周三  这样的，所以还是不行，很奇怪这和系统日期有啥关系。。

Batcher

3# 随风


看来你还没有真正理解那两个函数^_^
两个函数联合使用可以解决你的问题

ArdentMan

@Echo Off
If "%1" NEQ "" Goto Next
Set  /P time1=请输入时间（格式如：2011-07-13-00:03）
Set "ymd=%time1:~,10%"&Set /A h=1%time1:~11,2%%%100,n=1%time1:~14,2%%%100
MsHta VBscript:CreateObject("Wscript.Shell").Run("%~fs0 "^&DateAdd("n",-5,"%ymd% %h%:%n%"),1,0)(Window.Close)&&Exit
:Next
For /F "tokens=1-5 delims=-: " %%a In ("%1 %2") Do (
  Set "y=%%a"&Set "m=0%%b"&Set "d=0%%c"&Set "h=%%d"&Set "n=0%%e"
)
Echo %y%-%m:~-2%-%d:~-2%-%h%:%n:~-2%
Pause>NulCOPY

ArdentMan

这种输入格式好奇怪啊

随风

2# Batcher

函数中的算法都是从1970年起，得到它之后的N分钟的日期时间，我要的是指定日期时间之前的N分钟的日期时间.
cn-dos 的大牛的算法从来没弄懂过....

Batcher

调用函数DateToMins和MinsToDate
http://bbs.bathome.net/thread-3056-1-1.html