[文本处理] 批处理如何实现给文本内容添加行号？

wh1234567

文本内容比较多，但每行内容的前面没有序号，想用批处理自动给文本内容每行前面加个行号，请问如何写呢？
例如文本内容如下：
11.txt
需v师德师风
bdbdfbd-dfvd=dfd
231231323223123123232312323[fff]
sddfsfsfsd3231方便更方便
自动处理后格式为：
1-bdbdfbd-dfvd=dfd
2-231231323223123123232312323[fff]
3-sddfsfsfsd3231方便更方便
并输出到另外一个文本22.txt里

jingyu9575

@echo off
set i=1
>22.txt (for /f "delims=" %%s in (11.txt) do (
	setlocal enabledelayedexpansion
	<nul set /p "_=!i!"
	setlocal disabledelayedexpansion
	<nul set /p "_=-%%s"
	echo,
	set /a i+=1
))
复制代码

如果分隔符用冒号就简单了：

findstr /N ".*" 11.txt > 22.txt
复制代码

DAIC

sed = 11.txt | sed "N;s/\n/-/" > 22.txt
复制代码

DAIC

gawk "{print NR\"-\"$0}" 11.txt > 22.txt
复制代码

DAIC

powershell -c "foreach ($i in $(gc 11.txt)) {$n++; \"$n-\" + $i}" > 22.txt
复制代码

wh1234567

回复 2# jingyu9575


   为什么会出现!i!这种情况，不能全部正常处理

wh1234567

不想使用第三方程序，希望大虾们帮助下吧，

wh1234567

每行前面添加行号和固定字符（例如-或.或空格）

CrLf

hash /printf:"%d-%s",number,string /file 11.txt >22.txt
复制代码

CrLf

@echo off
(for /f "tokens=1* delims=:" %%a in ('findstr /n .* 11.txt') do echo %%a-%%b)>22.txt
复制代码

CrLf

@echo off
for /f %%a in ('find /c /v "" ^<11.txt') do set count=%%a
(for /l %%a in (1 1 %count%) do (
  setlocal enabledelayedexpansion
  set /p "str="&echo;%%a-!str!
  endlocal
))<11.txt >22.txt
复制代码

wh1234567

回复 10# CrLf


    哦，这个正常，感谢您了

CrLf

@echo off
((for /f "delims=" %%a in ('findstr /n .* 11.txt') do (
   set "str=%%a"
   set /a n+=1
   setlocal enabledelayedexpansion
   set "str=!str:*:=!"
   echo !n!-!str!
   endlocal
))>22.txt
复制代码

wh1234567

回复 11# CrLf


    这个不行，输不出

CrLf

@set @a=0;/*&echo off
findstr /n .* 11.txt |cscript /nologo /e:jscript %0 >22.txt
pause&exit
*/
str = WScript.StdIn.ReadAll()
str = str.replace(/^(\d+):/gm,'$1-')
WScript.Echo(str)
复制代码