qixiaobin0715

你是说只删除倒数第一行和倒数第二行符合要求的行吗？

qixiaobin0715

效率应当不算高，未经测试。

@echo off
setlocal enabledelayedexpansion
for %%a in (*.txt) do (
    for /f %%x in ('type "%%a"^|find /c /v ""') do set m1=%%x&set /a m2=m1-1
    set n=0
    (for /f "delims=" %%i in ('type "%%a"') do (
        set /a n+=1
        set str=%%i
        for %%y in (， 。 “ ” ？ ！) do set str=!str:%%y=!
        if not !n!==!m1! if not !n!==!m2! echo,%%i
        if !n!==!m1! if not "!str!"=="%%i" echo,%%i
        if !n!==!m2! if not "!str!"=="%%i" echo,%%i
    ))>#%%a
)
pause
复制代码

qixiaobin0715

回复 7# DDDYJQ1
这样可能效率要高一点，只有这水平了：

@echo off
setlocal enabledelayedexpansion
for %%a in (*.txt) do (
    for /f %%x in ('type "%%a"^|find /c /v ""') do set /a m=%%x-1
    set n=0
    (for /f "delims=" %%i in ('type "%%a"') do (
        set /a n+=1
        if !n! lss !m! (
            echo,%%i
        ) else (
            set str=%%i
            for %%y in (， 。 “ ” ？ ！) do set str=!str:%%y=!
            if not "!str!"=="%%i" echo,%%i
        )
    ))>#%%a
)
pause
复制代码

qixiaobin0715

这样效率应当可以，用到了临时文件：

@echo off
setlocal enabledelayedexpansion
for %%a in (*.txt) do (
    set n=0
    (for /f "delims=" %%i in ('type "%%a"^|sort /+100') do (
        set /a n+=1
        if !n! lss 3 (
            set str=%%i
            for %%y in (， 。 “ ” ？ ！) do set str=!str:%%y=!
            if not "!str!"=="%%i" echo,%%i
        ) else (
            echo,%%i
        )
    ))>a.temp
sort /+100 a.temp>#%%a
)
del a.temp
pause
复制代码

qixiaobin0715

如果每行字符较多，可以将sort /+100的数增加，比如sort /+1000。总而言之sort后面的数字一定要大于最长行的字符数。

qixiaobin0715

文本内容千变万化，写代码按通常情况即可，考虑太多这代码就复杂了，可根据具体情况进行调整。