已解决：如何判断wim映像的版本

766266yyn

请教各位老师：
    批处理如何判断 WinPE 的映像文件，如 boot.wim 的版本，只判断是 Win10 或 Win11 即可，
    不需要判断 Win10 之前版本。

感谢 “批处理之家”
感谢 77七 老师辛苦，我的难题（对我一样的小白来说）完美解决，代码总结如下：

一、该版本需要以管理员运行，否则出错

1. @echo off
   
2. setlocal EnableExtensions
   
3. set "wimFile=D:\yynTemp\boot-11.wim"
   
4. 
   
5. :: 重要提醒
   
6. echo. && echo.
   
7. echo 重要提醒：
   
8. echo =========
   
9. echo. && echo 该程序需要以管理员身份运行,否则会出错！
   
10. echo. && echo. && pause
    
11. cls
    
12. if not exist %wimFile% (
    
13.     echo.
    
14.     echo.
    
15.     echo [错误] 找不到映像文件：%wimFile%
    
16.     timeout /t 5 /nobreak >nul
    
17.     exit /b 1
    
18. )
    
19. set "Build="
    
20. for /f "tokens=2 delims=:" %%a in ('dism /English /Get-WimInfo /WimFile:"%wimFile%" /index:1^| findstr /b /c:"Version :"') do (
    
21.         for /f "tokens=3 delims=." %%b in ("%%a") do set "Build=%%b"
    
22.     )
    
23. if not defined Build (
    
24.     echo. && echo. && echo [错误] 无法读取 WIM 映像版本
    
25.     echo.
    
26.     pause
    
27.     exit /b 1
    
28. )
    
29. if %Build% GEQ 22000 (
    
30.     echo. && echo. && echo %wimFile% 版本是：Windows 11
    
31.     echo.
    
32.     pause && exit /b 11
    
33. ) else (
    
34.     echo. && echo. && echo %wimFile% 版本是：Windows 10
    
35.     echo.
    
36.     pause && exit /b 10
    
37. )
    

复制代码

二、该版本可自动提权

1. @echo off
   
2. setlocal EnableExtensions
   
3. title WinPE 映像版本检测
   
4. rem ============================================================
   
5. rem 自动申请管理员权限
   
6. rem ============================================================
   
7. fltmc >nul 2>&1
   
8. if errorlevel 1 (
   
9.     echo 正在申请管理员权限...
   
10.     powershell.exe -NoProfile -ExecutionPolicy Bypass -Command ^
    
11.         "Start-Process -FilePath '%~f0' -Verb RunAs -WorkingDirectory '%~dp0'"
    
12.     exit /b
    
13. )
    
14. rem ============================================================
    
15. rem 在这里设置需要检测的 WIM 映像路径
    
16. rem ============================================================
    
17. set "WimFile=E:\sources\boot.wim"
    
18. rem WIM 映像索引
    
19. set "WimIndex=1"
    
20. rem ============================================================
    
21. rem 检查文件是否存在
    
22. rem ============================================================
    
23. if not exist "%WimFile%" (
    
24.     echo.
    
25.     echo [错误] 找不到 WIM 映像文件：
    
26.     echo "%WimFile%"
    
27.     echo.
    
28.     pause
    
29.     exit /b 1
    
30. )
    
31. 
    
32. echo.
    
33. echo 正在检测：
    
34. echo "%WimFile%"
    
35. echo.
    
36. rem ============================================================
    
37. rem 读取映像内部版本号
    
38. rem 例如：Version : 10.0.26100
    
39. rem ============================================================
    
40. set "ImageVersion="
    
41. set "Build="
    
42. 
    
43. for /f "tokens=2 delims=:" %%A in ('
    
44.     dism.exe /English /Get-WimInfo /WimFile:"%WimFile%" /Index:%WimIndex% 2^>nul ^
    
45.     ^| findstr /b /c:"Version :"
    
46. ') do (
    
47.     for /f "tokens=* delims= " %%B in ("%%A") do set "ImageVersion=%%B"
    
48. )
    
49. 
    
50. if not defined ImageVersion (
    
51.     echo [错误] 无法读取 WIM 映像版本。
    
52.     echo.
    
53.     echo 可能原因：
    
54.     echo 1. WIM 文件损坏
    
55.     echo 2. 指定的映像索引不存在
    
56.     echo 3. 当前 DISM 版本无法读取该映像
    
57.     echo.
    
58.     pause
    
59.     exit /b 2
    
60. )
    
61. rem 从 10.0.26100 中提取 26100
    
62. for /f "tokens=3 delims=." %%A in ("%ImageVersion%") do set "Build=%%A"
    
63. 
    
64. if not defined Build (
    
65.     echo [错误] 无法解析映像内部版本号：%ImageVersion%
    
66.     echo.
    
67.     pause
    
68.     exit /b 3
    
69. )
    
70. 
    
71. echo 映像内部版本：%ImageVersion%
    
72. echo 系统构建号：%Build%
    
73. echo.
    
74. rem ============================================================
    
75. rem Windows 11 从 Build 22000 开始
    
76. rem ============================================================
    
77. if %Build% GEQ 22000 (
    
78.     echo 判断结果：Windows 11 WinPE
    
79. ) else (
    
80.     echo 判断结果：Windows 10 WinPE
    
81. )
    
82. 
    
83. echo.
    
84. pause
    
85. endlocal

复制代码

766266yyn

各位老师，来过路过，不要错过 ...

aloha20200628

一般而言，版本号范围：
   10.0.1xxxx 是 Win10
   大于或等于 10.0.22xxx 是 Win11

Five66

dism查找列出映像的文件, 然后看sidebyside中组件的版本, 一般组件版本号就是系统版本, 大概就像这样子
\Windows\WinSxS\x86_microsoft-windows-packagemanager_31bf3856ad364e35_10.0.17763.1_none_817f127d9310406d

1. dism /list-image /imagefile:boot.wim /index:1|findstr /i \windows\winsxs
   
2. pause

复制代码

或者7z之类的直接从wim中提取特定文件, 然后获取提其的文件的版本号, 比如

1. 7z e boot.wim -o%temp% 1\Windows\System32\kernel32.dll
   
2. 7z t "%temp%\kernel32.dll"
   
3. pause

复制代码

766266yyn

Five66 发表于 2026-7-30 14:25
dism查找列出映像的文件, 然后看sidebyside中组件的版本, 一般组件版本号就是系统版本, 大概就像这样子
\Wi ...

谢谢老师，我是小白不会弄啊

flashercs

1. @echo off
   
2. for /f "skip=1 tokens=2 delims=: " %%A in ('dism /Get-ImageInfo /ImageFile:"E:\sources\boot.wim" /index:1^|findstr "Version"') do set "version=%%A"
   
3. echo version=%version%
   
4. if "%version%" geq "10.0.22000" (
   
5.   echo win11
   
6. ) else (
   
7.   echo win10
   
8. )
   
9. pause

复制代码

766266yyn

flashercs 发表于 2026-7-30 19:16

谢谢老师，好像不对，判断Win10的映像显示是Win10, 判断的映像是Win11PE的，但运行结果也显示是Win10

flashercs

766266yyn 发表于 2026-7-30 20:02
谢谢老师，好像不对，判断Win10的映像显示是Win10, 判断的映像是Win11PE的，但运行结果也显示是Win10 ...

我不知道如何判断版本号;AI说版本号小于等于19045是win10,反之是win11;
最好测试install.wim

77七

AI:
Windows 10 和 Windows 11 的主版本号都是 10.0，需要判断内部版本号 Build：

Build < 22000：Windows 10 WinPE
Build >= 22000：Windows 11 WinPE

CheckWinPE.bat

1. @echo off
   
2. setlocal EnableExtensions
   
3. 
   
4. rem 用法：CheckWinPE.bat "D:\sources\boot.wim"
   
5. set "WimFile=%~1"
   
6. 
   
7. if not defined WimFile set "WimFile=%~dp0boot.wim"
   
8. 
   
9. if not exist "%WimFile%" (
   
10.     echo [错误] 找不到映像文件：
    
11.     echo %WimFile%
    
12.     exit /b 1
    
13. )
    
14. 
    
15. set "Build="
    
16. 
    
17. for /f "tokens=2 delims=:" %%A in ('
    
18.     dism.exe /English /Get-WimInfo /WimFile:"%WimFile%" /Index:1 2^>nul ^| findstr /b /c:"Version :"
    
19. ') do (
    
20.     for /f "tokens=3 delims=." %%B in ("%%A") do set "Build=%%B"
    
21. )
    
22. 
    
23. if not defined Build (
    
24.     echo [错误] 无法读取 WIM 映像版本。
    
25.     exit /b 1
    
26. )
    
27. 
    
28. echo 检测到 Build：%Build%
    
29. 
    
30. if %Build% GEQ 22000 (
    
31.     echo 判断结果：Windows 11 WinPE
    
32.     exit /b 11
    
33. ) else (
    
34.     echo 判断结果：Windows 10 WinPE
    
35.     exit /b 10
    
36. )

复制代码

调用：

1. call CheckWinPE.bat "D:\sources\boot.wim"
   
2. 
   
3. if errorlevel 11 (
   
4.     echo 这是 Windows 11 PE
   
5. ) else if errorlevel 10 (
   
6.     echo 这是 Windows 10 PE
   
7. ) else (
   
8.     echo 检测失败
   
9. )

复制代码

其中 /English 很重要，可以避免中文、英文系统的 DISM 输出字段不同。通常 boot.wim 的索引 1 和索引 2 使用相同系统版本，所以读取 /Index:1 即可。

766266yyn

77七 发表于 2026-7-31 03:44
AI:
Windows 10 和 Windows 11 的主版本号都是 10.0，需要判断内部版本号 Build：

谢谢老师，运行闪退

77七

766266yyn 发表于 2026-7-31 07:15
谢谢老师，运行闪退

先按名字保存第一段代码；然后保存第二段代码为test.bat，代码最后添加一行 pause

766266yyn

77七 发表于 2026-7-31 07:26
先按名字保存第一段代码；然后保存第二段代码为test.bat，代码最后添加一行 pause ...

已经测试了，问题在下面这一段，具体是dism失败

1. set "Build="
   
2. for /f "tokens=2 delims=:" %%a in ('
   
3.     dism /English /Get-WimInfo /WimFile:"D:\yynTemp\boot-10.wim" /index:1 >"D:\wimVer.txt" 2>&1^| findstr /b /c:"Version :"
   
4. ') do (
   
5.     for /f "tokens=3 delims=." %%b in ("%%a") do set "Build=%%b"
   
6. )
   
7. echo 检测到 Build：%Build%
   
8. pause
   
9. if not defined Build (
   
10.     echo [错误] 无法读取 WIM 映像版本。
    
11.     exit /b 1
    
12. )
    
13. 
    
14. echo 检测到 Build：%Build%
    

复制代码

ShowCode

766266yyn 发表于 2026-7-31 08:10
已经测试了，问题在下面这一段，具体是dism失败

请把dism报错信息发出来看看，我可以帮你修改。

766266yyn

ShowCode 发表于 2026-7-31 08:17
请把dism报错信息发出来看看，我可以帮你修改。

cmd 闪退，所以在终端管理员测试

ShowCode

766266yyn 发表于 2026-7-31 08:55
cmd 闪退，所以在终端管理员测试

2^>nul 这是BAT脚本文件的语法，在CMD测试的时候请把它删掉再试试。