[已解决]求助完善BAT脚本批量移动相同前缀文件名到相同前缀文件夹内

tttoi2000

文件名举例如下
H210-2025-XS13（字符长度不同）-1（数字长度4位，且为自然数，前面无零）-1（数字长度2位，且为自然数，前面无零）.pdf
H210-2025-XS13-1-1.pdf...H210-2025-XS13-1-99.pdf--->H210-2025-XS13-1
H210-2025-XS13-10-1.pdf...H210-2025-XS13-1-99.pdf--->H210-2025-XS13-10
H210-2025-XS13AC-1-1.pdf...H210-2025-XS13AC-1-99.pdf--->H210-2025-XS13AC-1
H210-2025-XS13AC-100-1.pdf...H210-2025-XS13AC-100-99.pdf--->H210-2025-XS13AC-100
H210-2025-X13AC-1000-1.pdf...H210-2025-X13AC-1000-99.pdf--->H210-2025-X13AC-1000
原BAT如下：
@echo off
for /f "tokens=1-4* delims=-" %%a in ('dir /b /a-d *-*-*-*-*.pdf') do (
        md "%%a-%%b-%%c-%%d" 2>nul
        move "%%a-%%b-%%c-%%d-*.pdf" "%%a-%%b-%%c-%%d" 2>nul
)
pause
有劳各位大侠，谢谢。

77七

哪里需要完善？

tttoi2000

移动时它会把
H210-2025-XS13-1-1.pdf、H210-2025-XS13-10-1.pdf、H210-2025-XS13-100-1.pdf会同时移到H210-2025-XS13-1文件夹里，想分归属到相应文件夹里

77七

tttoi2000 发表于 2026-9-5 21:16
移动时它会把
H210-2025-XS13-1-1.pdf、H210-2025-XS13-10-1.pdf、H210-2025-XS13-100-1.pdf会同时移到H210 ...

1. @echo off
   
2. cd /d "%~dp0"
   
3. for /f "delims=" %%i in ('dir /b /a-d "*-*-*-*.pdf"') do (
   
4.         for /f "tokens=1-4 delims=-" %%a in ("%%~ni") do (
   
5.                 if not exist "%%a-%%b-%%c-%%d\" (
   
6.                         md "%%a-%%b-%%c-%%d\"
   
7.                 )
   
8.                 move "%%i" "%%a-%%b-%%c-%%d\"
   
9.         )
   
10. )
    
11. pause

复制代码

aloha20200628

tttoi2000 发表于 2026-9-5 21:16
移动时它会把
H210-2025-XS13-1-1.pdf、H210-2025-XS13-10-1.pdf、H210-2025-XS13-100-1.pdf会同时移到H210 ...

用 findstr 锚定每个字段及其数据类型，move 参数不用通配符 ...

test.bat （存放与 *.pdf 同目录）

1. @echo off &for /f "tokens=1-5 delims=-" %%a in (
   
2.    'dir /b /a-d "*-*-*-*-*.pdf" ^|findstr /i "[a-z0-9][0-9a-z]*-[0-9][0-9]*-[a-z0-9][a-z0-9]*-[0-9][0-9]*-[0-9][0-9]*.pdf" ') do (
   
3.    if not exist "%%a-%%b-%%c-%%d" md "%%a-%%b-%%c-%%d"
   
4.    move "%%a-%%b-%%c-%%d-%%e" "%%a-%%b-%%c-%%d" ) >nul 2>nul
   
5. exit/b

复制代码

holley

1. @echo off
   
2. setlocal
   
3. cd /d "%~dp0"
   
4. 
   
5. for /f "delims=" %%i in ('dir /b /a-d *.pdf') do (
   
6.     for /f "tokens=1-4* delims=-" %%a in ("%%~ni") do (
   
7.         md "%%a-%%b-%%c-%%d" 2>nul
   
8.         move /y "%%i" "%%a-%%b-%%c-%%d\" >nul 2>&1
   
9.     )
   
10. )
    
11. echo 归档完成
    
12. pause

复制代码

aloha20200628

   用 dir /b/a-d "*-*-*-*-*.pdf" 只能排除少于4个 - 分隔符的 pdf 文件（如果 move 采用 * 通配符也会放行更多的文件），用 findstr ... 可进一步匹配其中只有4个 - 分隔符的 pdf 文件，并同时匹配其每个字段的数据构成；
   如果当前目录中有多种命名格式混杂的 pdf 文件，采用上述 dir+findstr 组合过滤方法还是必要的...

tttoi2000

多谢三位大侠，三个方法都可以正常按本人需求使用。