设为首页收藏本站
切换到宽版

 找回密码
 注册
搜索
批处理之家»论坛 › 批处理专区: BAT CMD DOS › 开源原创工具 › wapi 调用win32 api
[新手上路]批处理新手入门导读[视频教程]批处理基础视频教程[视频教程]VBS基础视频教程[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动[批处理精品]CMD命令50条不能说的秘密[在线下载]第三方命令行工具[在线帮助]VBScript / JScript 在线参考
12下一页
返回列表 发新帖
查看: 323|回复: 22

wapi 调用win32 api

[复制链接]
went
发表于 6 天前 | 显示全部楼层 |阅读模式
本帖最后由 went 于 2026-11-13 23:20 编辑

可以调用一些简单的api,测试脚本放在1楼

  2. win32 api 调用

  4. wapi.exe 用法:

  6.   初始化         wapi -init [-debug]

  8.   释放资源       wapi -free

  10.   设置同步模式   wapi -sync,async

  12.   设置变量       wapi -set name { #num[b,o,h] |  @float | $var | str }

  14.   获取变量       wapi -get name [-str | -int | -float]

  16.   显示所有变量   wapi -show

  18.   显示变量内存   wapi -mshow name size [-offset 0] [-r radix] [-addr]

  20.   设置变量内存   wapi -mset name value [-offset 0] [-s,b,w,d,q] [-addr]

  22.   获取变量内存   wapi -mget name {-b,w,d,q,s} [-offset 0] [-addr]

  24.   填充变量内存   wapi -mfill name count value [-offset 0] [-s,b,w,d,q] [-addr]

  26.   调用API        wapi -call mod fun [args ...]

  28.   调用API并返回  wapi -rcall ret mod fun [args ...]

  30.   查看示例       wapi -sample

  32.   备注:
  33.       1.首次调用init初始化,后面调用清空所有变量,init和free请配套使用

  35.       2.$var表示变量的值,$$var表示取变量的地址,在call时可用

  37.       3.内置变量 $WAPI_FUN_0 ~ $WAPI_FUN_5,分别为有0~5个参数的回调函数,在call时可用

  39.       4.要操作float或int变量内存,请在mshow,mget,mset,mfill命令添加-addr开关

复制代码

这个是下载地址 https://gitee.com/wentlis/wapi/releases

评分

参与人数 1技术 +1 收起 理由
cutebe + 1 厉害！

查看全部评分

回复

举报

went
 楼主| 发表于 6 天前 | 显示全部楼层
本帖最后由 went 于 2026-11-13 22:17 编辑

示例 - 简单调用.bat
  1. @echo off & cd /d "%~dp0"

  3. rem wapi测试脚本

  5. wapi -init

  7. rem 对话框
  8. call :msgbox

  10. rem 获取控制台窗口文字
  11. call :get_title

  13. rem 设置控制台窗口文字
  14. call :set_title

  16. wapi -free

  18. pause&exit

  20. :msgbox
  21. wapi -call user32 MessageBoxA #0 "内容" "标题" #4
  22. goto :eof

  24. :get_title
  25. title 这是测试标题
  26. wapi -rcall hHeap kernel32 GetProcessHeap
  27. wapi -rcall lpMem kernel32 HeapAlloc $hHeap #0 #1024
  28. wapi -rcall hwnd  kernel32 GetConsoleWindow
  29. wapi -rcall len   user32   GetWindowTextA $hwnd $lpMem #1024
  30. wapi -get lpMem -str
  31. wapi -call kernel32 HeapFree $hHeap #0 $lpMem
  32. goto :eof

  34. :set_title
  35. wapi -rcall hwnd  kernel32 GetConsoleWindow
  36. wapi -call user32 SetWindowTextA $hwnd "这是设置的标题"
  37. goto :eof
复制代码
回复

举报

87zrjojo
发表于 5 天前 | 显示全部楼层
本帖最后由 87zrjojo 于 2026-11-10 09:37 编辑

感觉好高级。但怎么用，有没有更详细一说明？比如像MessageBoxA这样的模块是在哪里找到的，怎么用它的参数。能不能实现在win7以上系统中用命令行安装字体？因为直接复制字体到Fonts目录不能生效。感觉用你这个工具好像有可能解决。
回复

举报

cutebe
发表于 5 天前 | 显示全部楼层
本帖最后由 cutebe 于 2026-11-12 08:20 编辑
87zrjojo 发表于 2026-11-10 09:33
感觉好高级。但怎么用，有没有更详细一说明？比如像MessageBoxA这样的模块是在哪里找到的，怎么用它的参数 ...


加载字体，试试WinAPI：AddFontResource
测试字体可以仅用WinAPI，不复制也添加注册表。
发重启后字体仍可用，则加注册表。
  1. ::WAPI安装字体 拖入字体文件
  2. ::@echo off
  3. if "%~1"=="" echo 请拖入字体文件（.ttf/.otf）……&pause&goto :eof

  5. set "字体文件=%~1" %_字体_ttf_otf_%
  6. set "安装路径=C:\Windows\Fonts"
  7. call :安装字体 "%字体文件%" "%安装路径%"
  8. echo 安装完成。

  10. pause
  11. goto :eof
  12. ::结束

  14. :安装字体
  15. setLocal
  16. set "字体文件=%~1"
  17. set "字体名=%~n1"
  18. set "字体文件名=%~nx1"
  19. if "%~2"=="" (set "安装路径=%~dp1")else set "安装路径=%~2"
  20. if "%安装路径:~-1%"=="\" set "安装路径=%安装路径:~,-1%"
  21. ::复制与注册表，使重启有效
  22. copy/b/y "%字体文件%" "%安装路径%"
  23. reg add "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Fonts" /v "%字体名%" /d "%字体文件名%" /f

  25. wapi -init %_初始化wapi_%
  26. ::加载字体
  27. wapi -call gdi32 AddFontResourceA "%安装路径%\%字体文件名%"
  28. ::通知窗口，使当前有效
  29. ::wapi -call user32 SendMessageA #65535 #29 #0 #0
  30. ::能否直接支持16进制数0xF
  31. ::wapi -call user32 SendMessageA #0xFFFF #0x001D #0 #0
  32. wapi -free %_释放wapi_%
  33. endLocal
  34. goto :eof
复制代码
回复

举报

87zrjojo
发表于 5 天前 | 显示全部楼层
cutebe 发表于 2026-11-10 15:17
加载字体，试试WinAPI：AddFontResource

有没有具体点的操作步骤方法，实在不太懂该怎么传递或传递哪些参数
回复

举报

Five66
发表于 5 天前 | 显示全部楼层
建议加上声明, 声明不要用此程序来调用winpai dll之外的其他dll, 其他dll的调用约定可能不同
int是dword, str不支持转义吧, 没有byte方式的读取和写入, 不方便用HeapAlloc分配的内存来呈现结构
还有吐槽下winapi很难用, 是真的难用, 各种的例外与限制, 不能一步到位真的呛, 像是一个WriteConsoleW, 第三个参数内部明明会进行计算对比却不给你自动, 非得先计算一次, 而且不支持重定向, 想要WriteConsoleW不出问题, 实际上还得多调用4个左右的其他api
回复

举报

went
 楼主| 发表于 4 天前 | 显示全部楼层
本帖最后由 went 于 2026-11-11 00:16 编辑
Five66 发表于 2026-11-10 23:56
建议加上声明, 声明不要用此程序来调用winpai dll之外的其他dll, 其他dll的调用约定可能不同
int是dword, s ...


c的dll没有测试,应该会闪退.二进制编辑后面会加入更新
回复

举报

went
 楼主| 发表于 4 天前 | 显示全部楼层
本帖最后由 went 于 2026-11-13 22:49 编辑

1.1版更新了用管道输出,效率会更慢,但可以被for /f捕获输出
添加了内置的回调函数 $WAPI_FUN_0 ~ $WAPI_FUN_5,使用如下:
  1. @echo off & cd /d "%~dp0"
  2. rem 遍历窗口句柄并获取窗口标题
  3. wapi -init
  4. wapi -async
  5. wapi -rcall hHeap kernel32 GetProcessHeap
  6. wapi -rcall lpMem kernel32 HeapAlloc $hHeap #0 #1024
  7. for /f "tokens=1,2" %%i in ('wapi -call user32 EnumWindows $WAPI_FUN_2 #123') do (
  8.         wapi -rcall len user32 GetWindowTextA #%%i $lpMem #1024
  9.         set "title="
  10.         for /f "delims=" %%a in ('wapi -get lpMem -str') do set "title=%%a"
  11.         call echo 窗口句柄:%%i 窗口标题:%%title%%
  12. )
  13. wapi -free

  15. pause&exit
复制代码

评分

参与人数 1技术 +1 收起 理由
cutebe + 1 有意义的更新

查看全部评分

回复

举报

cutebe
发表于 3 天前 | 显示全部楼层
87zrjojo 发表于 2026-11-10 16:51
有没有具体点的操作步骤方法，实在不太懂该怎么传递或传递哪些参数

更新在4楼
回复

举报

cutebe
发表于 3 天前 | 显示全部楼层
went 发表于 2026-11-11 00:08
1.1版更新了用管道输出,效率会更慢,但可以被for /f捕获输出
添加了内置的回调函数 $WAPI_FUN_0 ~ $WAPI_FUN ...

数值能直接支持16进制吗？这样0xFAE7之类的就不用转换了
回复

举报

went
 楼主| 发表于 3 天前 | 显示全部楼层
本帖最后由 went 于 2026-11-12 22:38 编辑
cutebe 发表于 2026-11-12 08:23
数值能直接支持16进制吗？这样0xFAE7之类的就不用转换了


更新了,可以输入#fa7eh表示
后缀 b,o,h分别表示 2进制,8进制,16进制数字

评分

参与人数 1技术 +1 收起 理由
cutebe + 1 好哇。

查看全部评分

回复

举报

went
 楼主| 发表于 3 天前 | 显示全部楼层
Five66 发表于 2026-11-10 23:56
建议加上声明, 声明不要用此程序来调用winpai dll之外的其他dll, 其他dll的调用约定可能不同
int是dword, s ...

1.1版更新了内存编辑功能 wapi -sample有详细用法
回复

举报

went
 楼主| 发表于 前天 22:13 | 显示全部楼层
示例 - 遍历进程.bat 建议管理员权限运行
  1. @echo off & cd /d "%~dp0"
  2. setlocal enabledelayedexpansion
  3. set "PATH=%PATH%;.."

  5. rem 遍历进程

  7. rem 初始化
  8. wapi -init >nul

  10. rem 枚举所有进程id
  11. wapi -rcall hHeap kernel32 GetProcessHeap || goto :err
  12. wapi -rcall lpMem1 kernel32 HeapAlloc $hHeap #8h #4096 || goto :err
  13. wapi -rcall lpMem2 kernel32 HeapAlloc $hHeap #8h #1024 || goto :err
  14. wapi -set n1 #0
  15. wapi -call Psapi EnumProcesses $lpMem1 #4096 $$n1 || goto :err

  17. rem 循环每个进程
  18. set "count=0"
  19. for /f "delims=" %%i in ('wapi -get n1 -int') do set /a "count=%%i/4"
  20. echo 进程总数: %count%
  21. echo ----------
  22. for /l %%i in (1,1,%count%) do (
  23.         set /a "offset=0,id=0"
  24.         rem 计算lpMem中进程id的偏移
  25.         set /a "offset=(%%i-1)*4"
  26.         rem 取出进程id,取1个dword(4字节)
  27.         for /f "delims=" %%a in ('wapi -mget lpMem1 -offset !offset! -d') do set "id=%%a"
  28.         echo 进程id: !id!
  29.         rem 打开进程
  30.         wapi -rcall hProc kernel32 OpenProcess #1000h #0 #!id!
  31.         rem 初始化缓冲区
  32.         wapi -mfill lpMem2 1024 0 -b
  33.         rem 获取进程文件
  34.         wapi -rcall len Psapi GetProcessImageFileNameA $hProc $lpMem2 #1024
  35.         rem 打印
  36.         wapi -get lpMem2 -str
  37.         echo ----------------------
  38. )

  40. wapi -free >nul

  42. pause&exit

  44. :err
  45. echo 调用失败
  46. pause&exit
复制代码
回复

举报

went
 楼主| 发表于 前天 22:18 | 显示全部楼层
示例 - 桌面绘制小圆.bat
  1. @echo off & cd /d "%~dp0"
  2. set "PATH=%PATH%;.."

  4. rem 桌面绘制小圆

  6. rem 初始化
  7. wapi -init >nul || ( echo 初始化失败 & pause&exit )
  8. wapi -sync

  10. rem 获取屏幕尺寸
  11. for /f "delims=" %%i in ('wapi -call user32 GetSystemMetrics #0') do set "sx=%%i"
  12. for /f "delims=" %%i in ('wapi -call user32 GetSystemMetrics #1') do set "sy=%%i"
  13. echo 屏幕尺寸: %sx%x%sy%

  15. rem 初始化dc和画刷
  16. wapi -rcall hwnd user32 GetDesktopWindow
  17. wapi -rcall hdc user32 GetDC $hwnd
  18. rem 红色实心画刷(#00BBGGRR)
  19. wapi -rcall hbrush gdi32 CreateSolidBrush #ffh
  20. wapi -rcall ret gdi32 SelectObject $hdc $hbrush

  22. rem 在屏幕4个角绘制4个半径为r小圆
  23. set r=50
  24. set /a "left=0,top=0,right=r,bottom=r"
  25. wapi -call gdi32 Ellipse $hdc #%left% #%top% #%right% #%bottom%
  26. set /a "left=sx-r,top=0,right=sx,bottom=r"
  27. wapi -call gdi32 Ellipse $hdc #%left% #%top% #%right% #%bottom%
  28. set /a "left=0,top=sy-r,right=r,bottom=sy"
  29. wapi -call gdi32 Ellipse $hdc #%left% #%top% #%right% #%bottom%
  30. set /a "left=sx-r,top=sy-r,right=sx,bottom=sy"
  31. wapi -call gdi32 Ellipse $hdc #%left% #%top% #%right% #%bottom%

  33. rem 释放dc
  34. wapi -rcall ret user32 ReleaseDC $hwnd $hdc

  36. rem 显示变量
  37. wapi -show

  39. rem 释放资源
  40. wapi -free >nul

  42. pause&exit
复制代码
回复

举报

went
 楼主| 发表于 前天 22:29 | 显示全部楼层
示例 - 获取时间.bat
  1. @echo off & cd /d "%~dp0"
  2. set "PATH=%PATH%;.."

  4. rem 获取系统时间
  5. rem https://learn.microsoft.com/zh-cn/windows/win32/api/sysinfoapi/nf-sysinfoapi-getlocaltime
  6. rem https://learn.microsoft.com/zh-cn/windows/win32/api/minwinbase/ns-minwinbase-systemtime

  8. rem 初始化
  9. wapi -init >nul

  11. rem 申请内存
  12. wapi -rcall hHeap kernel32 GetProcessHeap || goto :err
  13. wapi -rcall lpMem1 kernel32 HeapAlloc $hHeap #8h #16 || goto :err

  15. rem 获取本地时间
  16. wapi -call kernel32 GetLocalTime $lpMem1

  18. rem 取出成员
  19. for /f "delims=" %%i in ('wapi -mget lpMem1 -w -offset 0') do set "year=%%i"
  20. for /f "delims=" %%i in ('wapi -mget lpMem1 -w -offset 2') do set "month=%%i"
  21. for /f "delims=" %%i in ('wapi -mget lpMem1 -w -offset 4') do set "week=%%i"
  22. for /f "delims=" %%i in ('wapi -mget lpMem1 -w -offset 6') do set "day=%%i"
  23. for /f "delims=" %%i in ('wapi -mget lpMem1 -w -offset 8') do set "hour=%%i"
  24. for /f "delims=" %%i in ('wapi -mget lpMem1 -w -offset 10') do set "min=%%i"
  25. for /f "delims=" %%i in ('wapi -mget lpMem1 -w -offset 12') do set "sec=%%i"
  26. for /f "delims=" %%i in ('wapi -mget lpMem1 -w -offset 14') do set "msec=%%i"

  28. echo %year%年%month%月%day%日 %hour%:%min%:%sec%.%msec% 周%week%

  30. wapi -free >nul

  32. pause&exit

  34. :err
  35. echo 调用失败
  36. pause&exit
复制代码

评分

参与人数 1技术 +1 收起 理由
cutebe + 1 如果wapi能直接输出cmd变量就不用那么多for ...

查看全部评分

回复

举报

下一页 »
12下一页
返回列表 发新帖
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 注册

本版积分规则

Archiver|手机版|小黑屋|批处理之家 ( 渝ICP备10000708号 )

GMT+8, 2026-11-15 07:19

Powered by Discuz! X3.5

© 2001-2026 Discuz! Team.

快速回复 返回顶部 返回列表