[已解决]如何快速找出文件夹当中掉的件数

tttoi2000

一堆文件夹，文件尾数号为1--999自然递增
示例：
X:\1\
H205J-2002-JX14-3-1.pdf
H205J-2002-JX14-3-2.pdf
H205J-2002-JX14-3-3.pdf
H205J-2002-JX14-3-4.pdf
H205J-2002-JX14-3-5.pdf
H205J-2002-JX14-3-6.pdf
当中某些文件夹会是
H205J-2003-JX14-3-1.pdf

H205J-2003-JX14-3-3.pdf

H205J-2003-JX14-3-5.pdf
H205J-2003-JX14-3-6.pdf
有什么方法可以快速找出，并形成文本显示
X文件差2件
H205J-2003-JX14-3-2.pdf
H205J-2003-JX14-3-4.pdf。。。。

aloha20200628

假设各目录中被处理的均是命名格式如  *-*-*-*-n 的 pdf 文件，检测其中 n 字段丢失的文件...
test-1.bat

1. @echo off &setlocal &for /d /r %%D in (*) do (
   
2.    pushd "%%D" &setlocal enabledelayedexpansion &set "ls=," &set "mx=1"
   
3.    for /f "delims=" %%F in ('dir /b/a-d *.pdf') do set "nF=%%~nF" &for /f "tokens=5 delims=-" %%n in ("%%~nF") do set "ls=!ls!%%n," &if %%n gtr !mx! set "mx=%%n"
   
4.    for /f "tokens=1-4 delims=-" %%a in ("!nF!") do set "f=%%a-%%b-%%c-%%d-"
   
5.    echo,%%D 丢失如下文件：
   
6.    for /l %%x in (1,1,!mx!) do if "!ls!"=="!ls:*,%%x,=!" echo,!f!%%x.pdf
   
7.    endlocal &popd )
   
8. pause&exit/b

复制代码

如果每个子目录均假设应有 1-999 个连续命名排序的 *.pdf 文件，则须改用以下代码...
test-2.bat

1. @echo off &setlocal &set "xF=pdf"
   
2. (for /d /r %%D in (*) do (
   
3.    pushd "%%D" &setlocal enabledelayedexpansion &set "nF=" &set "ls=," &set "mx=999"
   
4.    for /f "delims=" %%F in ('dir /b/a-d *.%xF%') do (
   
5.       if not defined nF for /f "tokens=1-4 delims=-" %%a in ("%%~nF") do set "f=%%a-%%b-%%c-%%d-"
   
6.       for /f "tokens=5 delims=-" %%n in ("%%~nF") do set "ls=!ls!%%n," )
   
7.    echo,%%D 丢失如下文件：
   
8.    for /l %%n in (1,1,!mx!) do if "!ls!"=="!ls:*,%%n,=!" echo,!f!%%n.%xF%
   
9.    endlocal &popd ))>"检查结果.txt"
   
10. explorer /select, "检查结果.txt" &exit/b

复制代码

77七

如果序号是 2 4 5 ，需要补充的范围是1-5 还是2-5？

tttoi2000

77七 发表于 2026-11-12 19:55
如果序号是 2 4 5 ，需要补充的范围是1-5 还是2-5？

因为是连续号，需要查出漏号
=================
显示文本提示：

X需要补充：1 3。。。。

77七

[quote]tttoi2000 发表于 2026-11-12 20:03
因为是连续号，需要查出漏号
=================
显示文本提示：

1. @echo off
   
2. cd /d "%~dp0"
   
3. 
   
4. set n=0
   
5. set str=
   
6. for /d %%d in (*) do (
   
7.         pushd "%%d"
   
8.         setlocal enabledelayedexpansion
   
9.         (
   
10.                 echo folder "%%d"
    
11.                 for /l %%l in (999 -1 1) do (
    
12.                         if not defined str (
    
13.                                 if exist "*-%%l.pdf" (
    
14.                                         for %%i in ("*-%%l.pdf") do (
    
15.                                                 set "file=%%i|"
    
16.                                         )
    
17.                                         set "str=!file:-%%l.pdf|=!"
    
18.                                 )
    
19.                         ) else if not exist "*-%%l.pdf" (
    
20.                                 echo !str!-%%l.pdf
    
21.                                 set /a n+=1
    
22.                         )
    
23.                 )
    
24.                 echo --- !n!
    
25.                 echo=
    
26.         ) >> "%~dp0log.txt"
    
27.         endlocal
    
28.         popd
    
29. )
    
30. pause

复制代码

tttoi2000

77七 发表于 2026-11-12 23:21
[quote]tttoi2000 发表于 2026-11-12 20:03
因为是连续号，需要查出漏号
=================

谢谢大侠，正是我想要的。

aloha20200628

已补齐2楼 test-2.bat 代码》将屏显结果写入 "检查结果.txt" 文件
再给一个 bat+powershell 版本如下（存为test.bat 运行）超越2楼纯批版本的优势》一。可不限 *.pdf 文件名被 - 字符分割的固定个数，只检查最后一个数值字段；二。也不受限路径文件名中如 ！等特殊字符的干扰。

test.bat

1. <# ::
   
2. @echo off &setlocal &set "x=.pdf" &set "mx=999"
   
3. powershell -nop -c "$x='%x%'; $mx=%mx%; iex(${%~f0}|out-string)">"检查结果.txt"
   
4. explorer /select, "检查结果.txt" &exit/b
   
5. #>
   
6. dir -r -dir *|%{
   
7.    $d=$_.fullname; $ls=@()
   
8.    dir -file "$d\*.pdf" |%{
   
9.       $nf=$_.basename; $f=$nf -replace '\d+$'
   
10.       $n=[int]($nf -replace '.*-(\d+)$', '$1'); $ls+=$n }
    
11.    "$d 丢失如下文件："
    
12.    (1..$mx)|%{if($_ -notin $ls){$f+$_+$x}} }
    
13. exit

复制代码

tttoi2000

aloha20200628 发表于 2026-11-13 12:38
已补齐2楼 test-2.bat 代码》将屏显结果写入 "检查结果.txt" 文件
再给一个 bat+powershell 版本如下（存为 ...

因为每个文件夹里文件尾号不是截止999，所以不用全数字查到999，要不然会查出多余的空号，只用查出文件夹中间存在的漏号即可