批处理怎样判断errorlevel返回值？

gobi918 · 发表于 2012-5-10 22:37:59

同事要我帮忙编一个IP扫描的批处理，自己尝试编了下面的代码，发现一个问题，
不管ping通不通都只写入到succeedList文本中，貌似errorlevel就没起到作用，
以前也遇到过，但是换另一种方式解决的，这个问题属于旧病，还请大侠拯救，为感~

@echo off
color 3f
title IPscan
set IPstart=
set IPPool=
set /p IPstart=请输入起始IP:
set /p IPpool=请输入IP范围:
echo=
echo IP连通性检测中...
for /F "tokens=1-4 delims=." %%a in ("%IPstart%") do (
set AA=%%a
set BB=%%b
set CC=%%c
set DD=%%d
)
set /a IPpools=%DD%+%IPpool%
for /l %%i in (%DD%,1,%IPpools%) do (
ping -n 1 %AA%.%BB%.%CC%.%%i>nul
if %errorlevel% EQU 0 (
echo %AA%.%BB%.%CC%.%%i>>succeedList.txt
) else (
echo %AA%.%BB%.%CC%.%%i>>failedList.txt
)
)
pause

复制代码

gawk · 发表于 2012-5-10 22:49:42

你打算付多少钱？100还是1000？

秋风·飞扬 · 发表于 2012-5-11 10:43:29

回复 2# gawk

!!

neorobin · 发表于 2012-5-11 10:55:08

本帖最后由 neorobin 于 2012-5-11 11:10 编辑

回复 1# gobi918

楼主试下下面的, 第 3 行中的 TAB 字符 (ASCII 9) 可能被论坛处理成了若干空格, 可以自己编辑并还原, 但仅影响输出的格式.

@echo off & setlocal enabledelayedexpansion & color 0a & mode con lines=2
:remself 用 ping.exe 和 arp 来扫描和显示局域网活动 IP.
set "TAB= "
set /a sendCnt=2
set /p sendCnt=Please input the number of echo requests to send(default=!sendCnt!^):
for /f "tokens=2 delims= " %%i in ('mode ^| findstr "列"') do set /a cols=%%i-11
(set /a rate=0)&(set lastPct=)
arp -d
for /f "tokens=3-6 delims=.: " %%a in ('ipconfig /all^|find /i "default gateway"') do (
if "%%b" neq "" (
set "total=254"
for /f %%h in ("%%a.%%b.%%c.%%d") do set "IPDefaultGateway=%%h"
for /l %%v in (1,1,!total!) do (
start /b ping -n !sendCnt! %%a.%%b.%%c.%%v>nul
echo Pinging %%a.%%b.%%c.%%v...
set /a pct=%%v*100/total+1000
if "!pct:~0,2!" equ "10" (set pct= !pct:~2!) else set "pct=!pct:~1!"
set /a n=%%v*cols / total
if !n! gtr !rate! (call :reflesh) else if "!lastPct!" neq "!pct!" (call :reflesh)
)
)
)
echo. & title waiting...
:wait
2>nul (
wmic process where "Caption='ping.exe'" get Caption|find /i /c "ping.EXE" && goto :wait
)
title PingScan 扫描完成.
set /a cnt=1000
>IPList (
echo 序号!TAB!IP 地址!TAB!!TAB!MAC 地址!TAB!!TAB!!TAB!主机名
echo ===============================================================
for /f "tokens=2" %%m in ('arp -a^|findstr /ic:"!IPDefaultGateway! "') do (
echo !cnt:~-3!!TAB!!IPDefaultGateway!!TAB!%%m!TAB!"网关"
)
set /a cnt+=1
for /f "tokens=2 delims=[]" %%t in ('ping -n 1 %computername% ^| find "["') do (
for /f "tokens=4" %%m in ('nbtstat -a "!computername!"^|findstr /ic:"MAC Address"') do (
for /f "delims=" %%M in ("%%m") do echo !cnt:~-3!★!TAB!%%t!TAB!%%M!TAB!!computername!
)
)
for /f "tokens=1-2" %%a in ('arp -a^|findstr /ic:"dynamic"') do (
if not "%%a"=="!IPDefaultGateway!" (
for /f "delims=<" %%H in ('nbtstat -A %%a^|findstr /ic:"<00> UNIQUE"') do (
set /a cnt+=1
set hostname=%%H
call :trim hostname
echo !cnt:~-3!!TAB!%%a!TAB!%%b!TAB!!hostname!
)
)
)
)
start notepad IPList
echo. & (<nul set /p=PingScan 扫描完成. 任意键退出...) & >nul pause
del IPList
exit /b
:reflesh
set "tt=!pct!%%"&(for /l %%j in (1,1,!rate!) do set tt=!tt!^>)&(title !tt!)
set /a rate=n
set "lastPct=!pct!"
exit /b
:trim strVar
if "!%1:~-1!" equ " " set "%1=!%1:~0,-1!" & call :trim %1
if "!%1:~0,1!" equ " " set "%1=!%1:~1!" & call :trim %1
exit /b

复制代码

plp626 · 发表于 2012-5-12 19:29:01

获取制表符

@echo off
for /f "delims=U" %%a in ('cmd/u/cecho 唉')do set $09=%%a
echo %$09%///////////
pause

复制代码

顺便做个推广：更多字符获取 bathome.net 搜索关键字ascmap，或ascii

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

批处理怎样判断errorlevel返回值？

评分

：