批处理如何获取指定文件夹下每个txt文本除了第一行和空白行外的行数并添加到文件名里

cloudinamoy · 发表于 2013-8-18 23:00:48

本帖最后由 pcl_test 于 2016-8-9 10:39 编辑

BAT怎样统计文件夹下txt文档的行数并重命名文件？
我想统计文件夹下及子文件夹下所有txt文档的行数并重命名文件
确切地说，我想统计文本除了第一行其他所有行但不包含空行，假设a.txt统计出的行数是num，然后将该文件重命名为anum.txt，求助啊，折腾了好久没弄出了

terse · 发表于 2013-8-19 00:19:25

@echo off
for /f "delims=" %%i in ('dir /b /a-d /s *.txt') do (
(more +1 "%%i" |findstr . |find /v /c "")>$
for /f %%j in ($) do echo ren "%%i" %%~ni%%j%%~xi
)
del $
pause

复制代码

CrLf · 发表于 2013-8-19 01:59:31

调用第三方工具 sed 和 uniq：

@echo off
for /f "tokens=1*" %%a in ('findstr /s /n . *.txt 2>nul ^| sed "/[^:]*:1:/d;s/:.*//" ^| uniq -c') do (
ren "%%b" "%%~nb%%a.txt"
)

复制代码

cloudinamoy · 发表于 2013-8-19 19:15:49

回复 2# terse

怎么找不到重命名的文件？

cloudinamoy · 发表于 2013-8-19 19:16:33

回复 3# CrLf

第三方工具不懂啊

cloudinamoy · 发表于 2013-8-19 19:42:00

根据上面的启发写出来了，谢谢！

@echo off
setlocal ENABLEDELAYEDEXPANSION
@set filepath=G:\批处理\20130819
for /r %filepath% %%a in (*.txt) do (
@set /a num=0
for /f " skip=1 " %%b in (%%a) do (set /a num+=1)
ren %%a %%~na!num!%%~xa
)
pause

复制代码

terse · 发表于 2013-8-19 21:08:29

回复 4# cloudinamoy
去掉后面 echo 即可

cloudinamoy · 发表于 2013-8-19 21:34:57

回复 7# terse

哦，是哦，怎么没看出来，谢啦~

gawk · 发表于 2013-8-19 22:08:35

回复 5# cloudinamoy

不懂没关系，下载之后放到system32文件夹下面就能直接调用了。

cloudinamoy · 发表于 2013-8-20 13:10:56

回复 9# gawk

哦，谢谢！

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文本处理] 批处理如何获取指定文件夹下每个txt文本除了第一行和空白行外的行数并添加到文件名里