wankoilz

find /c /v ""
这是什么意思呢，居然结果直接就是个数字...不解..

keen

@echo off
for /f "tokens=1 delims=:" %%i in ('findstr /n .* a.txt') do set a=%%i
echo %a%&pause
复制代码

cainiao736

14楼的好牛，学到了find的用法

rat

ding 14L.
Use the debug.exe:

@for /f "skip=1 tokens=2" %%a in ('more /e +1 "%~f0"^|debug^|find ":0110"') do @set/an=0x%%a-4&call echo %%n%%&pause>nul&exit/b
a100
CMP     BYTE PTR [BX+0111],0D
JNZ     010B
INC     BYTE PTR [0110]
INC     BX
LOOP    0100
INT     20

nlist.txt
l111
g
d110l1
q
复制代码

energy2009

楼上的汇编写的什么，感觉您好牛啊!
麻烦注释下。。。3Q！

sjzong

find 命令真厉害！！

keen

find /o 法:

@echo off
for /f "delims=:" %%i in ('findstr /o .* list.txt') do set /a n+=1
echo 总共有%n%行！&pause>nul
复制代码

Batcher

加上多余的/o开关会影响效率的吧？

其它几种方法：

@echo off
for /f "tokens=1 delims=:" %%a in ('findstr /n .* a.txt') do (
    set RowNum=%%a
)
echo %RowNum%
rem 10万行文本的测试结果：3分14.46秒
rem 15:45:22.25
rem 100000
rem 15:48:36.71
复制代码

@echo off
for /f "tokens=2 delims=:" %%a in ('find /v /c "" a.txt') do (
    set "RowNum=%%a"
    goto :print
)
:print
set "RowNum=%RowNum: =%"
echo %RowNum%
rem 10万行文本的测试结果：8.95秒
rem 15:54:04.05
rem 100000
rem 15:54:13.00
复制代码

@echo off
for /f %%a in (a.txt) do (
        set /a RowNum+=1
)
echo,%RowNum%
rem 10万行文本的测试结果：5.20秒
rem 15:51:30.55
rem 100000
rem 15:51:35.75
复制代码

@echo off
for /f %%a in ('type a.txt ^| find /c /v ""') do (
        set "RowNum=%%a"
)
echo,%RowNum%
rem 10万行文本的测试结果：2.92秒
rem 15:57:54.64
rem 100000
rem 15:57:57.56
复制代码

keen

针对这个题目(list.txt文本中只有很少的内容)，没有考虑效率。
当然，如果list.txt中的内容很多的话，效率的确是问题！！！
我只是想着一题多解。
谢谢指正。

wjjy

@echo off
for /f %%i in ('findstr  /n  "$" a.txt') do  set/a a+=1
echo %a%
pause
复制代码

keen

哥们，好像少了一行？

研究发现，当a.txt中最后的光标放在最后一行的下一行时，计算正确。
如果最后的光标跟最后一行是一行，计算结果少一行。
所以  "$"  效果不是很好。

建议，还是把"$" 改成 ".*"

[ 本帖最后由 keen 于 2009-5-6 09:40 编辑 ]

sjzong

@echo off
for /f "tokens=1 delims=:" %%i in ('findstr /n .* a.txt') do set a=%%i
echo 总行数（包括空行）是：%a%
set/a b=0
for /f "tokens=1 delims=:" %%i in ('findstr /n . a.txt') do set/a b+=1
echo 总行数（扣除空行）是：%b%
pause
复制代码

[ 本帖最后由 sjzong 于 2009-5-6 23:04 编辑 ]

sjzong

find /c /v "" ：将显示不包含指定字符串的行数。指定字符串为分号内的内容，（这边""我认为是空的，不知这样认为行吗？）
例如：find /c /v "a"  是计算不包括字符a的行的总数
假设有a.txt文件，内容如下：
acbda
dendf
sdds
a
b
de
运行命令 find /c /v "a" a.txt
结果：4
运行命令 find /c /v "d" a.txt
结果：2

[ 本帖最后由 sjzong 于 2009-5-6 23:36 编辑 ]

wq1282

原帖由 plp626 于 2008-6-11 19:10 发表
文件非空行数：
findstr/n . list.txt|find /c /v ""
文件总行数（包括空行）：
type list.txt|find /c /v ""

文件非空行数：
复制内容到剪贴板代码:
findstr/n . list.txt|find /c /v ""文件总行数（包括空行）：
复制内容到剪贴板代码:
type list.txt|find /c /v ""很强

lovelymorning

findstr /xvn .* a.txt

for /f "delims=:" %%a in ('findstr /xvn .* a.txt') do (echo 总有:%%a行)




find /c /v /n "" a.txt
for /f "tokens=2 delims=:" %%a in ('find /c /v /n "" a.txt') do (echo 总有:%%a行)

[ 本帖最后由 lovelymorning 于 2009-6-29 16:12 编辑 ]