[已解决]批处理对比两个文本，如何给一个文本添加一次顺序序号？

xp3000 · 发表于 2023-1-8 08:50:55

文本.txt对应文本.log
文本2.txt对应文本2.log
文本3.txt对应文本3.log
文本4.txt对应文本4.log

文本.txt：

送胡大
　　荆门不堪别，况乃潇湘秋。
　　何处遥望君，江边明月楼。
送狄宗亨
　　秋在水清山暮蝉，洛阳树色鸣皋烟。
　　送君归去愁不尽，又惜空度凉风天。
送窦七
　　清江月色傍林秋，波上荧荧望一舟。
　　鄂渚轻帆须早发，江边明月为君留。
送柴侍御
　　沅水通波接武冈，送君不觉有离伤。
　　青山一道同云雨，明月何曾是两乡？
送郭司仓
　　映门淮水绿，留骑主人心。
　　明月随良掾，春潮夜夜深。
送任五之桂林
　　楚客醉孤舟，越水将引掉。
　　山为两乡别，月带千里貌。
　　羁谴同缯纶，僻幽闻虎豹。
　　桂林寒色在，苦节知所效。
送李十五
　　怨别秦楚深，江中秋云起。
　　天长杳无隔，月影在寒水。
送张四
　　枫林已愁暮，楚水复堪悲。
　　别后冷山月，清猿无断时。
芙蓉楼送辛渐
　　寒雨连江夜入吴，平明送客楚山孤。
　　洛阳亲友如相问，一片冰心在玉壶。

复制代码

文本.log:

送胡大
送狄宗亨
送窦七
送柴侍御
送郭司仓
送任五之桂林
送李十五
送张四
芙蓉楼送辛渐

复制代码

读取文本.log后，查找文本.txt，将当内容相同时，便在前面添加一个序号和《》，变成：

1、《送胡大》
　　荆门不堪别，况乃潇湘秋。
　　何处遥望君，江边明月楼。
2、《送狄宗亨》
　　秋在水清山暮蝉，洛阳树色鸣皋烟。
　　送君归去愁不尽，又惜空度凉风天。
3、《送窦七》
　　清江月色傍林秋，波上荧荧望一舟。
　　鄂渚轻帆须早发，江边明月为君留。
4、《送柴侍御》
　　沅水通波接武冈，送君不觉有离伤。
　　青山一道同云雨，明月何曾是两乡？
5、《送郭司仓》
　　映门淮水绿，留骑主人心。
　　明月随良掾，春潮夜夜深。
6、《送任五之桂林》
　　楚客醉孤舟，越水将引掉。
　　山为两乡别，月带千里貌。
　　羁谴同缯纶，僻幽闻虎豹。
　　桂林寒色在，苦节知所效。
7、《送李十五》
　　怨别秦楚深，江中秋云起。
　　天长杳无隔，月影在寒水。
8、《送张四》
　　枫林已愁暮，楚水复堪悲。
　　别后冷山月，清猿无断时。
9、《芙蓉楼送辛渐》
　　寒雨连江夜入吴，平明送客楚山孤。
　　洛阳亲友如相问，一片冰心在玉壶。

复制代码

只添加一次，如果碰到重复的，只在首个出现的前面添加序号，
比如文本.txt
送张四是8、《送张四》，
芙蓉楼送辛渐是9、《芙蓉楼送辛渐》，
如果碰到

送张四
　　枫林已愁暮，楚水复堪悲。
　　别后冷山月，清猿无断时。
芙蓉楼
芙蓉楼送辛渐
芙蓉楼送辛渐
　　寒雨连江夜入吴，平明送客楚山孤。
　　洛阳亲友如相问，一片冰心在玉壶。

复制代码

替换为：

8、《送张四》
　　枫林已愁暮，楚水复堪悲。
　　别后冷山月，清猿无断时。
芙蓉楼
9、《芙蓉楼送辛渐》
芙蓉楼送辛渐
　　寒雨连江夜入吴，平明送客楚山孤。
　　洛阳亲友如相问，一片冰心在玉壶。

复制代码

hfxiang · 发表于 2023-1-8 09:12:19

如不介意，可用第3方工具gawk（ http://bcn.bathome.net/tool/4.1.0/gawk.exe ）来实现

gawk "NR==FNR{text[$0] = NR "、《" $0 "》";next}{if($0 in text){$0=text[$0]}}1" 文本.log 文本.txt>修改后的文本.txt

复制代码

注意，要确保“文本.log” 及 “文本.txt” 已保存为ANSI编码格式

xp3000 · 发表于 2023-1-8 09:49:27

本帖最后由 xp3000 于 2023-1-10 13:44 编辑

谢谢，如果碰到两首诗同名会出错，怎么修改

77七 · 发表于 2023-1-8 14:16:09

本帖最后由 77七于 2023-1-8 14:21 编辑

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /b /a-d *.txt') do (
set "fileName=%%~ni"
if exist "!fileName!.log" (
for /f "delims=" %%a in (!fileName!.log) do (
set "_%%a=ture"
)
set /a "num=0"
for /f "delims=" %%b in ('findstr /n .* !fileName!.txt') do (
set "str=%%b"
set "str=!str:*:=!"
if defined _!str! (
if defined #!str! (
>>xxx.temp echo,!str!
) else (
set /a num=num+1
set "#!str!=ture"
>>xxx.temp echo,!num!、《!str!》
)
) else (
>>xxx.temp echo,!str!
)
)
move /y xxx.temp !fileName!.txt
)
)
endlocal
pause

复制代码

我太菜了..写了好多..并且有一个问题，如果一个标题在多个log内存在，会有异常，也算变相查重了吧，如果没需要，我再试试修改

xp3000 · 发表于 2023-1-8 19:20:22

本帖最后由 xp3000 于 2023-1-11 12:20 编辑

谢谢，可以用就行，在两首诗同名时确实会出错

一个文本，两首同名不同内容的诗

WHY · 发表于 2023-1-8 23:33:49

本帖最后由 WHY 于 2023-1-8 23:39 编辑

@echo off
cd /d "%~dp0"
for %%i in (*.txt) do (
if exist "%%~ni.log" (
setlocal enabledelayedexpansion
for /f "delims=" %%j in ('type "%%~ni.log"') do (
set "_%%j=1"
)
(for /f "delims=" %%j in ('type "%%i" ^| findstr /n .*') do (
set "s=%%j"
set "s=!s:*:=!"
if defined _!s! (
set /a n+=1
echo;!n!、《!s!》
set "_!s!="
) else (
echo;!s!
)
)) > "%%i.~tmp"
endlocal
move "%%i.~tmp" "%%i"
)
)
pause

复制代码

xp3000 · 发表于 2023-1-9 08:45:24

谢谢各位帮忙,
确实标题重复的都不能处理.
文本.txt

岳阳楼
春色醉巴陵，阑干落洞庭。
水吞三楚白，山接九疑青。
空阔鱼龙气，婵娟帝子灵。
何人夜吹笛，风急雨冥冥。
岳阳楼
岳阳楼
岳阳楼上日衔窗，影到深潭赤玉幢。
怅望残春万般意，满棂湖水入西江。
黄鹤楼
　　昔人已乘黄鹤去，此地空余黄鹤楼。
　　黄鹤一去不复返，白云千载空悠悠。
　　晴川历历汉阳树，芳草萋萋鹦鹉洲。
　　日暮乡关何处是，烟波江上使人愁。

复制代码

文本.log

岳阳楼
黄鹤楼
岳阳楼

复制代码

这种情况，代码都出现了问题

qixiaobin0715 · 发表于 2023-1-9 09:59:53

回复 7# xp3000
这样呢。所有文件必须保存为ANSI编码：

@echo off
for /f "delims=" %%a in ('dir /b /a-d *.log') do (
setlocal enabledelayedexpansion
(for /f "delims=" %%i in ('type "%%a"') do (
set _"%%i"=true
)
set n=0
for /f "delims=" %%j in ('type "%%~na.txt"') do (
if defined _"%%j" (
set /a n+=1
echo,!n!、《%%j》
set _"%%j"=
) else (
echo,%%j
)
))>New%%~na.txt
endlocal
)
pause

复制代码

xp3000 · 发表于 2023-1-9 10:13:44

处理后显示

1、《岳阳楼》
春色醉巴陵，阑干落洞庭。
水吞三楚白，山接九疑青。
空阔鱼龙气，婵娟帝子灵。
何人夜吹笛，风急雨冥冥。
岳阳楼
岳阳楼
岳阳楼上日衔窗，影到深潭赤玉幢。
怅望残春万般意，满棂湖水入西江。
2、《黄鹤楼》
　　昔人已乘黄鹤去，此地空余黄鹤楼。
　　黄鹤一去不复返，白云千载空悠悠。
　　晴川历历汉阳树，芳草萋萋鹦鹉洲。
　　日暮乡关何处是，烟波江上使人愁。

复制代码

第二个岳阳楼重复两次，
第二次出现的需要在第一个出现时追加序号，
这里没实现，也就是下面结果，空行需要保留

1、《岳阳楼》
春色醉巴陵，阑干落洞庭。
水吞三楚白，山接九疑青。
空阔鱼龙气，婵娟帝子灵。
何人夜吹笛，风急雨冥冥。
2、《岳阳楼》
岳阳楼
岳阳楼上日衔窗，影到深潭赤玉幢。
怅望残春万般意，满棂湖水入西江。
3、《黄鹤楼》
　　昔人已乘黄鹤去，此地空余黄鹤楼。
　　黄鹤一去不复返，白云千载空悠悠。
　　晴川历历汉阳树，芳草萋萋鹦鹉洲。
　　日暮乡关何处是，烟波江上使人愁。

复制代码

qixiaobin0715 · 发表于 2023-1-9 10:48:27

本帖最后由 qixiaobin0715 于 2023-1-9 10:56 编辑

回复 9# xp3000
理解有误，这样行否：

@echo off
for /f "delims=" %%a in ('dir /b /a-d *.log') do (
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('type "%%a"') do (
set _"%%i"=true
)
set n=1
set m=1
(for /f "tokens=1* delims=:" %%i in ('findstr /n .* "%%~na.txt"') do (
if defined _"%%j" (
if !m! equ 1 (
echo,!n!、《%%j》
set /a n+=1
) else (
echo,%%j
)
set m=2
) else (
echo,%%j
set m=1
)
))>New%%~na.txt
endlocal
)
pause

复制代码

xp3000 · 发表于 2023-1-9 11:04:36

谢谢，这个可以

WHY · 发表于 2023-1-9 14:04:06

本帖最后由 WHY 于 2023-1-9 14:27 编辑

回复 9# xp3000

试试

@if(0)==(0) echo off
cd /d "%~dp0"
set "dstDir=Result"
md "%dstDir%" 2>nul
dir /b *.log | cscript //nologo //e:jscript "%~f0" "%dstDir%"
pause & exit /b
@end
var dstDir = WSH.Arguments(0); //目标目录
var fso = new ActiveXObject('Scripting.FileSystemObject');
while( !WSH.StdIn.AtEndOfStream ){
var file1 = WSH.StdIn.ReadLine(); //log文件名
var file2 = file1.replace(/\.log$/i, '.txt'); //txt文件名
if( !fso.FileExists(file2) ) continue; //判断txt文件是否存在
var reg = getText(file1); //log文本用"|"拼接
var f = fso.OpenTextFile(file2, 1);
var str = f.ReadAll();
f.Close();
var i = 0;
str = str.replace(
new RegExp( '^(' + reg + ')((?:\\r?\\n|$)(?:\\1(?:\\r?\\n|$))*)', 'igm' ),
function(s0, s1, s2){
return '' + ++i + '、《' + s1 + '》' + s2;
}
)
fso.OpenTextFile(dstDir + '\\' + file2, 2, true).Write(str); //保存
}
function getText(file){
var f = fso.OpenTextFile(file, 1);
var arr = [], map = [];
while( !f.AtEndOfStream ){
var s = f.ReadLine();
if(/^\s*$/.test(s)) continue;
if(!map.hasOwnProperty(s)){
var s1 = s.replace(/[\\|.^$()[\]{}*?+-]/g, '\\$&'); //字符转义
arr.push(s1);
map[s] = true; //去重复
}
}
f.Close();
return arr.join('|');
}

复制代码

xp3000 · 发表于 2023-1-9 14:41:06

谢谢，学习了，可以用

xp3000 · 发表于 2023-1-10 09:00:23

回复 2# hfxiang

如何修复两首诗同名，会异常的问题？

WHY · 发表于 2023-1-10 13:31:11

@echo off
cd /d "%~dp0"
md "Result" 2>nul
for %%i in (*.log) do (
setlocal enabledelayedexpansion
for /f "delims=" %%j in ('type "%%i"') do (
set "_%%j=1"
)
(for /f "delims=" %%j in ('type "%%~ni.txt" ^| findstr /n .*') do (
REM 当前行
set "curStr=%%j"
set "curStr=!curStr:*:=!"
if defined _!curStr! (
if "!curStr!" == "!preStr!" (
echo;!curStr!
) else (
set /a n+=1
echo,!n!、《!curStr!》
)
) else (
echo;!curStr!
)
REM 上一行
set "preStr=!curStr!"
)) > "Result\%%~ni.txt"
endlocal
)
pause

复制代码

@echo off
cd /d "%~dp0"
md "Result" 2>nul
for %%i in (*.log) do (
gawk "NR==FNR{a[$0]=1}NR>FNR{if(a[$0]&&s!=$0){print ++i"、《"$0"》"}else print;s=$0}" "%%i" "%%~ni.txt" > "Result\%%~ni.txt"
)
pause

复制代码

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文本处理] [已解决]批处理对比两个文本，如何给一个文本添加一次顺序序号？

评分

评分

评分

评分

评分

评分

评分